Sorting problem in serial column

[kingston123]

After deleting entire row, no sorting took place in serial numbers. Serial numbers remain same.



I deleted a row between these two rows:

[gmayor]

Why would they change? There is nothing to suggest that they are anything but text. If you want the numbers to change you need to replace them with automatic numbering or re-apply the numbers. The following macro will replace the numbers with automatic numbering

Sub RenumberTable()
Dim oTable As Table
Dim oRng As Range
Dim i As Integer
    Set oTable = Selection.Tables(1)
    For i = 1 To oTable.Rows.Count    'start at 2 if there is a header row
        Set oRng = oTable.Range.Rows(i).Cells(1).Range
        oRng.End = oRng.End - 1
        oRng.Fields.Add Range:=oRng, _
        Type:=wdFieldAutoNum, _
        Text:="\*Arabic", _
        PreserveFormatting:=False
    Next i
    ActiveWindow.View.ShowFieldCodes = False
    Set oTable = Nothing
    Set oRng = Nothing
End Sub

and the next macro will simply renumber the column

Sub RenumberTable2()
Dim oTable As Table
Dim oRng As Range
Dim i As Integer
    Set oTable = Selection.Tables(1)
    For i = 1 To oTable.Rows.Count    'start at 2 if there is a header row
        Set oRng = oTable.Range.Rows(i).Cells(1).Range
        oRng.End = oRng.End - 1
        oRng.Text = i & Chr(46)
    Next i
    ActiveWindow.View.ShowFieldCodes = False
    Set oTable = Nothing
    Set oRng = Nothing
End Sub

[macropod]

Originally Posted by kingston123

After deleting entire row, no sorting took place in serial numbers. Serial numbers remain same.

Well, if you'd used Word's automatic numbering, that wouldn't be an issue, as those update dynamically. And, if you used SEQ fields for the numbering, a simple print preview would update them. But, if you typed them manually, then you'll have to re-type them - or adopt one of the other methods...