Moving body text from old files to new files (based on template)

macropod · #5 05-01-2017, 07:23 PM

In reality, all you should need to do is attach the new template to the existing files (or copies of them), then apply the new Style definitions to the documents you've attached the template to. For example, the following macro does that for all documents in a selected folder:

Code:

Sub UpdateDocumentTemplates()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, strDocNm As String, wdDoc As Document
strDocNm = ActiveDocument.FullName
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""
  If strFolder & "\" & strFile <> strDocNm Then
    Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
    With wdDoc
      .AttachedTemplate = "C:\Templates\SomeTemplate.dotm"
      .CopyStylesFromTemplate (.AttachedTemplate.FullName)
      .Close SaveChanges:=True
    End With
  End If
  strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub

Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function

Simply change "C:\Templates\SomeTemplate.dotm" to suit your requirements.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Need to find/replace text in many word files - but text is in embedded word files	semple.13	Word VBA	5	11-03-2015 01:20 PM
Moving Multiple Hyperlinked Files around	cole790	Word	1	12-08-2013 03:55 PM
Merging pst files and moving to NAS drive	riteoh	Outlook	0	10-02-2012 05:20 AM
Moving files from one template to another	Stephen0352	Word	4	03-05-2012 01:29 AM
moving data files	g48dd	Outlook	2	06-17-2011 01:18 PM