Converting html link to ms word link

[myUserNamez]

I consistently receive word documents that are littered with html links like <a href="http://example.com"> click me </a> is there a way using vba to convert this to a proper link in word, so it looks like, and acts like a standard link (i.e.) click me.

[gmayor]

You could do this with a macro e.g.

Sub ReplaceHTMLLinks()
Dim oRng As Range
Dim sLink As String
Dim sAddr As String
Dim sDisplay As String
Dim vLink As Variant
    Set oRng = ActiveDocument.Range
    With oRng.Find
        Do While .Execute(FindText:="\<a href=*\<\/a\>", MatchWildcards:=True)
            sLink = oRng.Text
            vLink = Split(sLink, Chr(34))
            sAddr = vLink(1)
            sDisplay = Replace(Mid(sLink, InStr(1, sLink, ">") + 2), " </a>", "")
            oRng.Text = ""
            oRng.Hyperlinks.Add Anchor:=oRng, _
                                Address:=sAddr, _
                                TextToDisplay:=sDisplay
            oRng.Collapse 0
        Loop
    End With
End Sub

[myUserNamez]

Thanks for the prompt reply, the code you supplied works a treat.