Quick part building blocks

lukegwilson96 · #1 12-13-2016, 03:18 AM

Can you use formulas to insert quick part building blocks?

For example if drop down box equals 'a' insert building block '1'

gmayor · #2 12-13-2016, 03:47 AM

You can with a macro. What sort of 'dropdown box' did you have in mind?

Charles Kenyon · #3 12-13-2016, 05:24 AM

You also can do it with an IF Field and an AutoText field or building block content control as the truetext or falsetext. It depends on the building block.

See Microsoft Word Field Maths Tutorial. This does not require a macro but it is not necessarily easy.

lukegwilson96 · #4 12-13-2016, 06:13 AM

Quote:

Originally Posted by gmayor

You can with a macro. What sort of 'dropdown box' did you have in mind?

Combo box content control

gmayor · #5 12-13-2016, 07:10 AM

With a combobox content control, title it GetBlock (or whatever) then in the
Insert a bookmark where you want the building block to be placed (say bmBlock)
Add the following code to a new module in the document project

Code:

Public Sub BBToBM(strBMName As String, strTemplate As String, strBBName As String)
Option Explicit
'Graham Mayor - http://www.gmayor.com
Dim oRng As Range
Dim iLen1 As Integer, iLen2 As Integer
    With ActiveDocument
        iLen1 = Len(ActiveDocument.Range)
        On Error GoTo lbl_Exit
        Set oRng = .Bookmarks(strBMName).Range
        Application.Templates(strTemplate). _
                BuildingBlockEntries(strBBName).Insert _
                Where:=oRng, _
                RichText:=True
        iLen2 = Len(ActiveDocument.Range)
        oRng.End = oRng.End + (iLen2 - iLen1)
        oRng.Bookmarks.Add strBMName
    End With
lbl_Exit:
    Set oRng = Nothing
    Exit Sub
End Sub

In the ThisDocument module of the active document project add the following. Change the template from "D:\Word 2016 Templates\Normal.dotm" to the full path of wherever the building blocks (here BB Name 1 and BB Name 2) are stored.

Code:

Option Explicit

Private Sub Document_ContentControlOnExit(ByVal ContentControl As ContentControl, Cancel As Boolean)
    If ContentControl.Title = "GetBlock" Then
        Select Case ContentControl.Range.Text
            Case "Item1"
                BBtoBM "bmBlock", "D:\Word 2016 Templates\Normal.dotm", "BB Name 1"
            Case "Item2"
                BBtoBM "bmBlock", "D:\Word 2016 Templates\Normal.dotm", "BB Name 2"
        End Select
    End If
End Sub

Then if you have two entries in the combobox = Item1 and Item2, when you leave the combo box having made your selection, the appropriate building block is written to the bookmark.

Save as a macro enabled document (or template). Change any of the names and paths involved to fit what you have.

lukegwilson96 · #6 12-13-2016, 07:34 AM

Quote:

Originally Posted by gmayor

With a combobox content control, title it GetBlock (or whatever) then in the
Insert a bookmark where you want the building block to be placed (say bmBlock)
Add the following code to a new module in the document project

Code:

Public Sub BBToBM(strBMName As String, strTemplate As String, strBBName As String)
Option Explicit
'Graham Mayor - http://www.gmayor.com
Dim oRng As Range
Dim iLen1 As Integer, iLen2 As Integer
    With ActiveDocument
        iLen1 = Len(ActiveDocument.Range)
        On Error GoTo lbl_Exit
        Set oRng = .Bookmarks(strBMName).Range
        Application.Templates(strTemplate). _
                BuildingBlockEntries(strBBName).Insert _
                Where:=oRng, _
                RichText:=True
        iLen2 = Len(ActiveDocument.Range)
        oRng.End = oRng.End + (iLen2 - iLen1)
        oRng.Bookmarks.Add strBMName
    End With
lbl_Exit:
    Set oRng = Nothing
    Exit Sub
End Sub

In the ThisDocument module of the active document project add the following. Change the template from "D:\Word 2016 Templates\Normal.dotm" to the full path of wherever the building blocks (here BB Name 1 and BB Name 2) are stored.

Code:

Option Explicit
 
Private Sub Document_ContentControlOnExit(ByVal ContentControl As ContentControl, Cancel As Boolean)
    If ContentControl.Title = "GetBlock" Then
        Select Case ContentControl.Range.Text
            Case "Item1"
                BBtoBM "bmBlock", "D:\Word 2016 Templates\Normal.dotm", "BB Name 1"
            Case "Item2"
                BBtoBM "bmBlock", "D:\Word 2016 Templates\Normal.dotm", "BB Name 2"
        End Select
    End If
End Sub

Then if you have two entries in the combobox = Item1 and Item2, when you leave the combo box having made your selection, the appropriate building block is written to the bookmark.

Save as a macro enabled document (or template). Change any of the names and paths involved to fit what you have.

Hi Thank you,

Ive been working on the IF method. I roughly know how to do it this way. The only thing I am missing is how do I relate to a combo box within a field formula?

Charles Kenyon · #7 12-13-2016, 10:46 AM

Quote:

Originally Posted by lukegwilson96

Hi Thank you,

Ive been working on the IF method. I roughly know how to do it this way. The only thing I am missing is how do I relate to a combo box within a field formula?

Study the IF field's structure. You need something to test. If it is the combo box, that needs to be bookmarked.

Did you look at the tutorial on field maths?

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Deleted 'Built In' Quick Part Building Blocks by accident!	duncan_bridge@hotmail.com	Word	3	07-22-2016 01:38 AM
Building Blocks / Quick Parts	houseofturner	Word	4	07-19-2016 07:24 AM
VBA Word - Building Block (AutoText) - Array - Replace Text with Specific Building Blocks	jc491	Word VBA	7	01-03-2016 10:34 PM
Word 2013: Building Blocks / Quick Parts - Form Question	EGoetz	Word VBA	2	12-05-2013 09:09 PM
Building blocks show correctly in dropdown, but wrong building block populates in doc	wordgirl123	Word	0	10-03-2013 08:30 AM