Bold a sentence containing an em dash

[jeffreybrown]

I have a doc with sentences containing an em dash in the middle.

How can I get all those sentences as bold?

Examples:
The Purpose and Method of Luke’s Gospel—Read Luke 1:1-4
Zacharias Ministers in the Temple—Read Luke 1:5-10

[macropod]

Unless your text spans an entire paragraph or an entire line delineated with manual line breaks, what you're asking for isn't possible. That's because Word has no Find/Replace tools for finding grammatical sentences. The same limitation applies to VBA.

[jeffreybrown]

Hi Paul,

Yes, the text spans an entire paragraph and there is a manual line break at the end.

[macropod]

Please clarify - paragraph breaks and manual line breaks are entirely different things.

[jeffreybrown]

The document is downloaded from the internet with manual line breaks (arrow pointing to the left), but I can easily change them to paragraph breaks if it's easier to perform the bold

[macropod]

Try a wildcard Find/Replace, where:
Find = [!^13^11]@^0151[!^13^11]@[^13^11]
Replace = ^&
and you specify the replacement format as bold. As a macro, this might be implemented along the following lines:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Text = "[!^13^11]@^0151[!^13^11]@[^13^11]"
    With .Replacement
      .ClearFormatting
      .Text = "^&"
      .Font.Bold = True
    End With
    .Forward = True
    .Wrap = wdFindContinue
    .Format = True
    .MatchWildcards = True
    .Execute Replace:=wdReplaceAll
  End With
End With
Application.ScreenUpdating = True
End Sub

[jeffreybrown]

Thank you Paul. Wish I could say I understand what's happening, but it works well.

[macropod]

The 'Find' is a wildcard expression that looks for:
• any series of characters other than a paragraph break or line break - [!^13^11]@
• followed by an em-dash - ^0151
• followed by any series of characters other than a paragraph break or line break - [!^13^11]@
• followed by a paragraph break or line break - [^13^11]
The 'Replace' expression retains what is found - ^&

For more details, see:
http://www.gmayor.com/replace_using_wildcards.htm
http://word.mvps.org/FAQs/General/UsingWildcards.htm

[jeffreybrown]

Yes thanks Paul. I had seen those two sites, just wasn't understanding how it was strung together.