Microsoft Office Forums

Go Back   Microsoft Office Forums > >

Reply
 
Thread Tools Display Modes
  #1  
Old 05-02-2016, 05:48 PM
hellsbells hellsbells is offline Track Changes incorporated into finished document Windows 10 Track Changes incorporated into finished document Office 2013
Novice
Track Changes incorporated into finished document
 
Join Date: May 2016
Posts: 1
hellsbells is on a distinguished road
Default Track Changes incorporated into finished document


Hi,

I have been given a document by one of my bosses. He wants me to take a document that we have been tracking changes - stop tracking the changes - and incorporate the comments and in the end have a completed document that has kept all strike through and underlined changes in the finished document so we can copy and paste them into another program that won't accept them unless they are in rich text format. Does anyone know how to do this? I am at a total loss.

Thank you
Reply With Quote
  #2  
Old 05-02-2016, 06:57 PM
macropod's Avatar
macropod macropod is offline Track Changes incorporated into finished document Windows 7 64bit Track Changes incorporated into finished document Office 2010 32bit
Administrator
 
Join Date: Dec 2010
Location: Canberra, Australia
Posts: 21,956
macropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond repute
Default

Word provides no tools for doing anything of that kind. Besides which some changes are impossible to express in a text form. Word tracks 18 kinds of change:
Insertion
Deletion
Property changed
Paragraph number changed
Field display changed
Revision marked as reconciled conflict
Revision marked as a conflict
Style changed
Replaced
Paragraph property changed
Table property changed
Section property changed
Style definition changed
Content moved from
Content moved to
Table cell inserted
Table cell deleted
Table cells merged
Would you really want to record a format change, for example, by crossing out all the text in the old format, then reinserting the same text with underlining in the new format? And how would that work if the format change involved a colour change, table cell insertions/deletions, etc.?

As for comments, how exactly would you incorporate those into a document in a sensible way, especially where tracked changes are involved?

Basically what you'd need to do is make two copies of the document - one with all changes rejected and another with all changes accepted, then manually strike out all the deleted text & formatting from the one with the rejected changes and copy into it and underline all the added text & formatting from the one with the accepted changes.

The following macro should ease the process - it turns all tracked additions, deletions & moves into underlined/struck-out text.
Code:
Sub LockRevisions()
Application.ScreenUpdating = False
Dim i As Long, RngRev As Range, RngMov As Range
With ActiveDocument
  .TrackRevisions = False
  For i = .Revisions.Count To 1 Step -1
    With .Revisions(i)
      Set RngRev = .Range
      Select Case .Type
        Case wdRevisionInsert
          .Accept
          RngRev.Font.ColorIndex = wdBlue
          RngRev.Font.Underline = wdUnderlineSingle
        Case wdRevisionDelete
          .Reject
          RngRev.Font.ColorIndex = wdRed
          RngRev.Font.StrikeThrough = True
        Case wdRevisionMovedFrom
          Set RngMov = .MovedRange
          .Reject
          RngMov.Text = RngRev.Text
          RngMov.Font.ColorIndex = wdGreen
          RngMov.Font.Underline = wdUnderlineSingle
          RngRev.Font.ColorIndex = wdGreen
          RngRev.Font.StrikeThrough = True
      End Select
    End With
  Next
End With
Set RngRev = Nothing: Set RngMov = Nothing
Application.ScreenUpdating = True
End Sub
You'd still need to explain how all the other tracked formatting changes, etc. and comments should be incorporated in the 'final'.
__________________
Cheers,
Paul Edstein
[Fmr MS MVP - Word]
Reply With Quote
Reply

Thread Tools
Display Modes


Similar Threads
Thread Thread Starter Forum Replies Last Post
Track Changes incorporated into finished document Undoing changes in a Word 2010 document with track changes on kennethc Word 1 08-10-2014 04:36 AM
Track Changes incorporated into finished document Everytime I open a new document Track Changes is always turned on when I type. ECCLA Word 3 08-07-2013 05:04 PM
Outlines: Formatting them After Finished Creating Them? tatihulot Word 3 12-19-2012 03:46 PM
Track Changes incorporated into finished document Error Code 5453 Word has finished searching the document Charles Kenyon Word VBA 2 05-17-2012 11:18 AM
Track changes after document has been edited bradsmih Word 1 04-08-2012 10:10 PM

Other Forums: Access Forums

All times are GMT -7. The time now is 08:20 AM.


Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2024, vBulletin Solutions Inc.
Search Engine Optimisation provided by DragonByte SEO (Lite) - vBulletin Mods & Addons Copyright © 2024 DragonByte Technologies Ltd.
MSOfficeForums.com is not affiliated with Microsoft