Word View isn't working

macropod · #7 01-20-2016, 10:22 PM

Your profile says you're using the same Word version and OS as me, but it's clear from your screenshot you're not using Word 2010. That explains why you don't see the 'One Page' option. Please correct your profile.

That said, the following macros, added to your Normal template's 'ThisDocument' module, should take care of the display issues for any documents you subsequently open/create. As coded, the macro zooms the document to whichever is the lesser of the nearest 10% zoom increment that fits the screen and the preferred zoom, which is managed by the line:
Const lZoom As Long = 110
This sets the preferred zoom % to 110%. If you prefer something else, change the 110 to suit.

Code:

Private Sub Document_New()
Call Document_Open
End Sub
 
Private Sub Document_Open()
'Preferred zoom %
Const lZoom As Long = 110
With ActiveWindow
  'Ignore any errors
  On Error Resume Next
  'Reduce flickering while changing settings
  .Visible = False
  'Switch to a single view pane
  .View.SplitSpecial = wdPaneNone
  'Switch to Normal mode
  .View.Type = wdNormalView
  With .ActivePane.View.Zoom
    'Set for a 1-page view
    .PageColumns = 1
    'Initialize for best fit
    .PageFit = wdPageFitBestFit
    'Round down to nearest 10%
    .Percentage = Int(.Percentage / 10) * 10
    'Test zoom % and reduce to 120% max
    If .Percentage > lZoom Then .Percentage = lZoom
  End With
  'Switch to Print Preview mode
  .View.Type = wdPrintView
  With .ActivePane.View.Zoom
    'Set for a 1-page view
    .PageColumns = 1
    'Initialize for best fit
    .PageFit = wdPageFitBestFit
    'Round down to nearest 10%
    .Percentage = Int(.Percentage / 10) * 10
    'Test zoom % and reduce to 120% max
    If .Percentage > lZoom Then .Percentage = lZoom
  End With
  'Display the Rulers
  .ActivePane.DisplayRulers = True
  'Restore the window now that we're finished
  .Visible = True
End With
End Sub

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Outlook 2013 view settings no longer working	languageservicesco	Outlook	0	10-28-2015 05:25 PM
trouble with formating between print view and outline view	johndill	Word	2	10-17-2014 06:32 AM
non working day view	mijam	Project	1	03-29-2014 10:52 AM
Contact view filter not working	gebobs	Outlook	2	03-10-2014 06:28 AM
How can I fix a print view problem that causes it to stop working.. Excel 2007, Vista	birdie123	Excel	0	08-18-2012 12:02 PM