Screen Shot Alignment in Word

[anu_gv]

Hi,

I am new to this forum, I searched this forum about my query but I couldn't find the solution.



I have 100 page document (Word 2007) contains multi-level steps, in each page I have minimum 2 screenshots I would like to align all off them with same indent on left and right. Is there a way to automate all the pages same.

NOTE: Since I have multilevel steps like 1.1, 1.1.2, 1.1.2.1, 1.1.2.1.2, etc., I am not able to align all the pages with same indentation.

Can anyone suggest to resolve this issue.

Regards
Anu

[macropod]

If they're all formatted as in-line with text, simply attaching them to a paragraph at the relevant level would achieve that (e.g. via the use of manual line breaks to separate the picture from the text). For anything else, you'd probably need a macro to do all the processing. However, regardless of macros and depending on the size of the pictures, such indentation is liable to result in pictures extending into the margin area - and even off the page. Do you really want that?

[anu_gv]

Hi Paul,

Thx for your response.

I would like to have all of them in the same size of screen shots with same left and right indent. At present I am manually reducing the sizes from individual pages, if there is anyway I can keep my screenshots starts at 2.5cm on left side and provide space of 2.5cm on right side.

Regards
Anu

[macropod]

It's easy enough to use a macro to format all the images so they're 5cm less than the page width or the margin width, then centre them horizontally on the page. For example, if the screen shots have been inserted as floating images:

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long, sWdth As Single
With ActiveDocument.Range
  With .Sections(1).PageSetup
    sWdth = .PageWidth - .LeftMargin - .RightMargin - .Gutter - CentimetersToPoints(5)
  End With
  For i = 1 To .ShapeRange.Count
    With .ShapeRange(i)
      .LockAspectRatio = True
      .Width = sWdth
      .RelativeHorizontalPosition = wdRelativeHorizontalPositionMargin
      .Left = wdShapeCenter
    End With
  Next
End With
Application.ScreenUpdating = True
End Sub

The same kind of thing can be done with screen shots that have been inserted in-line with the text but, depending on what else is in the paragraphs they're attached to, it might mess with some of your formatting.

[anu_gv]

Hi Paul,

I will try and let you know if my screen shot are aligned or not. Hopefully it doesn't mess up the other formats.

Regards
Anu

[anu_gv]

Hi Paul,

I Created document with 4 multi-level steps (1, 1.1, 1.1.1, 1.1.1.1 - 1.1.1.4), at the 4th level step (1.1.1.4, 2.1.1.4, 3.1.1.4 & 4.1.1.4) I have inserted the screen shot. I copied the code you have given and pasted into visual basic, I ran the macro by clicking "Run Sub/UserForm, the screen shot is out of range. Not Sure What is the mistake I am doing in Running Macro.

Regards
Anu

[anu_gv]

Hi Paul,

Any suggestion is appreciated. When I ran the macro, it doesn't change the size of screen shots. My screen shots are different sizes in each step.

I am willing to attach the document.

Regards
Anu

[macropod]

Originally Posted by anu_gv

I ran the macro by clicking "Run Sub/UserForm, the screen shot is out of range

I'm not sure what you mean by that.

Originally Posted by anu_gv

When I ran the macro, it doesn't change the size of screen shots.

You'll recall from post # that I mentioned that macro working with screen shots inserted as floating shapes. Different code is required for screen shots inserted as inlineshapes. Try:

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long, sWdth As Single
With ActiveDocument.Range
  With .Sections(1).PageSetup
    sWdth = .PageWidth - .LeftMargin - .RightMargin - .Gutter - CentimetersToPoints(5)
  End With
  For i = 1 To .InlineShapes.Count
    With .InlineShapes(i)
      .LockAspectRatio = True
      .Width = sWdth
      With .Range.Paragraphs(1)
        If Len(.Range.Text) = 2 Then
          .LeftIndent = 0
          .RightIndent = 0
          .Alignment = wdAlignParagraphCenter
        End If
      End With
    End With
  Next
End With
Application.ScreenUpdating = True
End Sub

Although the above code will resize all the inline screenshots, it will only centre those that have no other text in the same paragraph. That's so you don't end up with a mass of centred text.