how citation excluded in word count

Amazingt · #1 05-11-2014, 08:15 AM

Hi. How do i excluded word count for citation of referent in my work? i found it actually exist maybe some specific setting to enable it because practically i found there's people did it.

macropod · #2 05-11-2014, 08:28 AM

To exclude them, you would need to count the words in them; Word doesn't have an automatic way of doing this. The following macro will count all words in citations and the bibliography:

Code:

Sub CountReferenceWords()
Dim FtNt As Footnote, EndNt As Endnote
Dim Fld As Field, i As Long, j As Long, k As Long
With ActiveDocument
  For Each Fld In .Fields
    If Fld.Type = wdFieldCitation Then
      i = i + UBound(Split(Fld.Result, " ")) + 1
    ElseIf Fld.Type = wdFieldBibliography Then
      j = UBound(Split(Fld.Result, " ")) + 1
    End If
  Next
  For Each FtNt In .Footnotes
    For Each Fld In FtNt.Range.Fields
      If Fld.Type = wdFieldCitation Then
        k = k + UBound(Split(Fld.Result, " ")) + 1
      End If
    Next
  Next
  For Each EndNt In .Endnotes
    For Each Fld In EndNt.Range.Fields
      If Fld.Type = wdFieldCitation Then
        k = k + UBound(Split(Fld.Result, " ")) + 1
      End If
    Next
  Next
End With
MsgBox "Citation words in the body: " & i & vbCr & _
"Citation words in footnotes & endnotes: " & k & vbCr & _
"Bibliography words : " & j
End Sub

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Word Count Formula	clau_dos	Word VBA	1	08-27-2013 02:05 PM
Word Count	Richtriebe	Word	1	04-20-2013 11:09 AM
Inconsistent citation styles in word 2013	dylansmith	Word	2	01-26-2013 06:58 PM
Word Count in Excel	dallas	Excel	1	11-23-2011 09:20 AM
Word - citation language	jakudo	Word	0	04-20-2010 05:15 AM