Macrobutton shifts view when document is protected for forms

[Cosmo]

I have a Word form which has several tables containing text entry and checkbox fields. I have a macrobutton on one of the pages to run a macro, but once the form is protected for forms, clicking on the Macrobutton shifts focus to the next page where the first checkboxes are. This prevents users from being able to double click on the macrobutton to run the macro since the macrobutton is no longer in the same position for the second click. It doesn't seem to do this if the document is protected for comments or any other setting, just form fields.



Is this a known issue with macrobuttons and protected forms? Is there any other way to run a macro from a click in the document?

[Charles Kenyon]

When a user clicks anywhere in a document protected for forms (other than in an active formfield) the focus moves to a page with formfields that are active.

Assuming you are using legacy form fields, you can designate a macro to run on exit from a formfield.

You can put the following in an AutoOpen and AutoNew macro in your form template:

Sub AutoOpen()
' Set macro button response to one click rather than double-click
' Macro written by Charles Kenyon based on help from Bill Coan on newsgroup
'
   Options.ButtonFieldClicks = 1
'
End Sub

This makes a single click activate the macrobutton.

Making Forms with Microsoft Word

[Cosmo]

Originally Posted by Charles Kenyon

When a user clicks anywhere in a document protected for forms (other than in an active formfield) the focus moves to a page with formfields that are active.

Assuming you are using legacy form fields, you can designate a macro to run on exit from a formfield.

You can put the following in an AutoOpen and AutoNew macro in your form template:

Sub AutoOpen()
' Set macro button response to one click rather than double-click
' Macro written by Charles Kenyon based on help from Bill Coan on newsgroup
'
   Options.ButtonFieldClicks = 1
'
End Sub

This makes a single click activate the macrobutton.

Making Forms with Microsoft Word

Thanks, I'll look into that.

According to the help files for the 'Options' object:

Represents application and document options in Word. Many of the properties for the Options object correspond to items in the Options dialog box.

Is the ButtonFieldClicks an application-level setting? Do I need to reset it after my form is completed? Is this an option available in the UI?

I'm assuming there's no way to set this for the document so that it travels with the document without scripting.

[Charles Kenyon]

I believe it to be an application-level setting that applies to that Word session.
Haven't tested it.

I know of no way to set the document for this setting without a macro. Once the document is on a different machine, it will have no effect until the setting is run on that machine.

If the macro is in the template and a document based on the template is opened or created, it will be run so long as the document remains attached to the template.

It should be possible to first capture that option state in a document variable when the macro is run and return to that state in a macro that responds to the Document_Close event. I have not attempted this because, frankly, I want the option set this way on all of the machines in my office. I have a number of macrobutton field using checkbox autotext in my non-protected legacy forms.

Single-Click Checkboxes in non-protected forms

[Cosmo]

Originally Posted by Charles Kenyon

I believe it to be an application-level setting that applies to that Word session.
Haven't tested it.

I know of no way to set the document for this setting without a macro. Once the document is on a different machine, it will have no effect until the setting is run on that machine.

If the macro is in the template and a document based on the template is opened or created, it will be run so long as the document remains attached to the template.

It should be possible to first capture that option state in a document variable when the macro is run and return to that state in a macro that responds to the Document_Close event. I have not attempted this because, frankly, I want the option set this way on all of the machines in my office. I have a number of macrobutton field using checkbox autotext in my non-protected legacy forms.

Single-Click Checkboxes in non-protected forms

Thanks again. It does appear to be a document level setting, creating a new document retains the currently set value.

I believe I should be able to get away with using the 'WindowActivate' and 'WindowDeactivate' events to change and reset this value so that it won't affect any other documents the user has open at the time (just in case). I did a quick test, and that seems to be working.

[Charles Kenyon]

Originally Posted by Cosmo

Thanks again. It does appear to be a document level setting, creating a new document retains the currently set value.

I believe I should be able to get away with using the 'WindowActivate' and 'WindowDeactivate' events to change and reset this value so that it won't affect any other documents the user has open at the time (just in case). I did a quick test, and that seems to be working.

Thank you for the update. Again, I learn something new!

[Cosmo]

Originally Posted by Charles Kenyon

Thank you for the update. Again, I learn something new!

This is the code I ended up using in a MacroButton Controller class:

Option Explicit
Private WithEvents wordApp As Word.Application
Private currentButtonClick As Integer
Private TemplateDoc As Document
'*************************************************************************
' Initialize class - Create objects and set values to defaults.
'*************************************************************************
Private Sub Class_Initialize()
    currentButtonClick = Options.ButtonFieldClicks
    Set wordApp = Application
    Set TemplateDoc = ActiveDocument
    Call setButtonClick
End Sub
'*************************************************************************
' Terminate class - Cleanup code.
'*************************************************************************
Private Sub Class_Terminate()
    Call restoreButtonClick
    Set wordApp = Nothing
    Set TemplateDoc = Nothing
End Sub
'*************************************************************************
' Application EVENT HANDLERS
'*************************************************************************
Private Sub wordApp_DocumentBeforeClose(ByVal Doc As Document, Cancel As Boolean)
    If CheckDoc(Doc) Then
        Call restoreButtonClick
    End If
End Sub
Private Sub wordApp_WindowActivate(ByVal Doc As Document, ByVal Wn As Window)
    If CheckDoc(Doc) Then
        Call setButtonClick
    End If
End Sub
Private Sub wordApp_WindowDeactivate(ByVal Doc As Document, ByVal Wn As Window)
    If CheckDoc(Doc) Then
        Call restoreButtonClick
    End If
End Sub
''*************************************************************************
'' UTILITY functions
''*************************************************************************
Private Function CheckDoc(Doc As Document) As Boolean
    If Not (TemplateDoc Is Nothing) Then
        If Not (Doc Is Nothing) Then
            CheckDoc = (Doc = TemplateDoc)
        End If
    End If
End Function
Private Function setButtonClick()
    Options.ButtonFieldClicks = 1
End Function
Private Function restoreButtonClick()
    Options.ButtonFieldClicks = currentButtonClick
End Function

I appreciate the help, I wouldn't have known that there was a setting for this without your responses. Thanks again

[Charles Kenyon]

Very nice. Beyond my pay grade!