Showing 1 page at a time in Word 2011 at 100% zoom (Mac)

[UrbanEast]

The only way this works is if I go to View-->Zoom, click on "Many pages" and change it to 1x1. But this will only let me view at 87% zoom. If I press the up arrow to change that number, it shows 2 pages at a time.

Using Print view shows either 2 or 4 pages at a time depending on the zoom.

I'd rather not use Focus view since I need to format as well. Is there a way to view 1 page only at 100%?



Thanks in advane.

[macropod]

I use a macro to control the page display on my PC but, IIRC, you should be able to get what you want via Zoom>Many Pages>1*1>100%>OK.

[UrbanEast]

Macro,

I tried that earlier and unfortunately, it doesn't work. When I try what you suggested, the radio button either changes to something else, or it simply changes to two pages side-by-side.

What is the macro you use for this?

Thanks.

[macropod]

The macros I use are below. They go in the Normal template's 'ThisDocument' module.

Private Sub Document_New()
'Ignore any errors
On Error Resume Next
Call Document_Open
End Sub
 
Private Sub Document_Open()
With ActiveWindow
  'Ignore any errors
  On Error Resume Next
  'Reduce flickering while changing settings
  .Visible = False
  'Switch to a single view pane
  .View.SplitSpecial = wdPaneNone
  'Switch to Normal mode
  .View.Type = wdNormalView
  With .ActivePane.View.Zoom
    'Set for a 1-page view
    .PageColumns = 1
    'Initialize for best fit
    .PageFit = wdPageFitBestFit
    'Test zoom % and reduce to 120% max
    If .Percentage > 120 Then .Percentage = 120
  End With
  'Switch to Print Preview mode
  .View.Type = wdPrintView
  With .ActivePane.View.Zoom
    'Set for a 1-page view
    .PageColumns = 1
    'Initialize for best fit
    .PageFit = wdPageFitBestFit
    'Test zoom % and reduce to 120% max
    If .Percentage > 120 Then .Percentage = 120
  End With
  'Display the Rulers
  .ActivePane.DisplayRulers = True
  'Hide the mailmerge task pane
  CommandBars("Mail Merge Panes").Visible = False
  'Restore the window now that we're finished
  .Visible = True
End With
End Sub

As you can see from the code, I prefer something larger than 100%, but changing to 100% or 110% shouldn't affect the overall effect.