Convert endnote/footnote to regular text

Cobb78 · #1 05-20-2012, 01:27 PM

I am working on a file for someone which is full of footnotes/endnotes. I need to (for conversion to another filetype) make those in-text references (superscript LETTERS) become regular text (not linked notes). I have found a fix, but it replaces the notation letters with superscript numbers. It has no option to make it superscript letters. The author of the file is pretty adamant that he wants the footnote markers to be superscript letters.

Without manually typing in the 3,000+ superscript letters, is there a way of doing this?

Thank you in advance.

BC

macropod · #2 05-20-2012, 03:37 PM

Hi BC,

Trying to convert footnotes to plain text and keeping them on the same page(s) as the footnotes from which they were derived is a real minefield. Converting endnotes is much easier though. Try:

Code:

Sub UnLinkEndNotes()
Application.ScreenUpdating = False
Dim nRng As Range, eNote As Endnote, nRef As String
With ActiveDocument
  For Each eNote In .Endnotes
    With eNote
      With .Reference.Characters.First
        .Collapse wdCollapseStart
        .InsertCrossReference wdRefTypeEndnote, wdEndnoteNumberFormatted, eNote.Index
        nRef = .Characters.First.Fields(1).Result
        .Characters.First.Fields(1).Unlink
      End With
      .Range.Cut
    End With
    If .Range.EndnoteOptions.Location = wdEndOfSection Then
      Set nRng = eNote.Range.Sections.First.Range
    Else
      Set nRng = .Range
    End If
    With nRng
      .Collapse wdCollapseEnd
      .End = .End - 1
      If .Characters.Last <> Chr(12) Then .InsertAfter vbCr
      .InsertAfter nRef & " "
      With .Paragraphs.Last.Range
        .Style = "Endnote Text"
        .Words.First.Style = "Endnote Reference"
      End With
      .Collapse wdCollapseEnd
      .Paste
      If .Characters.Last = Chr(12) Then .InsertAfter vbCr
    End With
  Next
  For Each eNote In .Endnotes
    eNote.Delete
  Next
End With
Set nRng = Nothing
Application.ScreenUpdating = True
End Sub

Footnotes can be converted in essentially the same way, but they effectively become another series of endnotes.

franklekens · #3 11-19-2012, 04:49 AM

I've just tried this in a text in which I created a couple of endnotes (not containing text) but it seems to baulk at the line
" .Range.Cut"

Does anybody know what might be wrong?

macropod · #4 11-19-2012, 01:56 PM

Since your endnotes don't actually have any content, there is nothing to cut.

franklekens · #5 11-20-2012, 05:32 AM

Thank you. I'd been fiddling around with it on a test text, and noticed that indeed the notes have to contain text for it to work. (For my slightly odd purposes, I don't need actual text in the endnotes, but that's no problem. I can add dummy text and as soon as it's unliked it's easy enough to delete.)

In another version of Word it also balked at these lines:
.Style = "Endnote Text"
.Words.First.Style = "Endnote Reference"

Presumably this is because I have no "Endnote text" style defined in Word, or is that supposed to be a default style that's always there?

In any case, when I cut these two lines the macro did seem to work just fine. (For my purposes at least. I hope it is not doing something wrong that I haven't noticed yet. :-)

Bhaskaran · #6 07-11-2016, 06:23 AM

I used the above script, but some of the text deletion happened in the output.

Input:

EX: Some Text 1

<Heading>
Endnote Chapter 1
1 Endnote Text

The output showed like below:

Heading>
Endnote Chapter 1
1 Endnote Text

Can you please let me know how to retain the deleted text "<".

Sample Doc file attached. Please check and let me know.

Thanks in advance,
Bhaskar

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Macro to convert text to endnote?	Orifacious	Word VBA	27	03-29-2022 02:58 PM
Convert - EndNote to Word's endnotes	Boatwrenchv8	Word	3	05-17-2012 04:56 PM
Endnote in footnote?	kerstin	Word	2	06-26-2011 11:23 PM
Cross-reference endnote text	smed	Word	3	01-14-2011 03:34 PM
How do I have headers and footers appear as regular text for the whole document?	user908045	Word	0	03-13-2010 12:41 PM