Find and Execute

[cksm4]

Hello,

I am trying to find text in a table and then execute a command which involves focusing on a new selection/range. I know the change is my issue but I do not know how to overcome it. Any ideas??

 
With ActiveDocument
Selection.Find.ClearFormatting
With Selection.Find
   .Text = "TOC"
   .Replacement.Text = ""
   .Forward = True
   .Wrap = wdFindContinue
   .Format = False
   .MatchCase = False
   .MatchWholeWord = False
   .MatchWildcards = False
   .MatchSoundsLike = False
   .MatchAllWordForms = False
End With
While .Execute
    .MoveDown Unit:=wdLine, Count:=1
    .SelectCell
    ActiveDocument.Indexes.MarkEntry Range:=Selection.Range, _
        EntryAutoText:=SelectedText, CrossReference:="", CrossReferenceAutoText:="", _
        BookmarkName:="", Bold:=False, Italic:=False
Wend
End With

Thanks!

[macropod]

Hi cksm4,

Try something along the lines of:

Sub Demo()
Dim tRng As Range
With Selection
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "TOC"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
  End With
  While .Find.Execute
    With .Range
      If .Information(wdWithInTable) = True Then
        Set tRng = .Tables(1).Cell(.Cells(1).RowIndex + 1, .Cells(1).ColumnIndex).Range
        tRng.End = tRng.End - 1
        ActiveDocument.Indexes.MarkEntry Range:=tRng, EntryAutoText:=.Text, _
          CrossReference:="", CrossReferenceAutoText:="", BookmarkName:="", Bold:=False, Italic:=False
      End If
    End With
  Wend
End With
End Sub