Word Macro to search all tables

[silverspr]

Hello
I have four (4) tables in word, each with 9 columns with varying rows. In all instances the last row, column holds a field that sums values above it. I would like to have a macro that searches the last column and resets the values to zero (0) except for the last row. I've tried creating said macro, however it only runs if the cursor is positioned in a table and the macro runs within that table, I can't get the macro to programmatically move to the next table using the table index:


Dim C As Cell
Dim LastCell As Long
Dim i As Long

i = 1
For i = 1 To 4
Set tbl = ActiveDocument.Tables(i)
LastCell = ActiveDocument.Tables(i).Rows.Count - 1
Selection.SetRange _


Start:=Selection.Tables(i).Cell(2, 9).Range.Start, _
End:=Selection.Tables(i).Cell(LastCell, 9).Range.End
With Selection
For Each C In Selection.Cells
C.Range.Text = "0"
Next C
End With
Next i

Your help is appreciated, thx

[macropod]

Hi silverspr,

Try:

Sub Demo()
Dim oTbl As Table, i As Integer, j As Integer
For Each oTbl In ActiveDocument.Tables
  With oTbl
    j = .Columns.Count
    For i = 1 To .Rows.Count - 1
      .Cell(i, j).Range.Text = "0"
    Next
  End With
Next
End Sub

[silverspr]

Thanks Paul,
Works wonderfully....and much more sophisticated than my solution. One more small problem...although I said I only had 4 tables, there are actually 6, but I only want the macro to edit the first 4. How to control this programmatically...thats why I thought I could use the table index....or was my intent.

thanks
dale

[macropod]

Hi Dale,

Try:

Sub Demo()
Dim i As Integer, j As Integer, k As Integer
With ActiveDocument
  For i = 1 To 4
    With .Tables(i)
      j = .Columns.Count
      For k = 1 To .Rows.Count - 1
        .Cell(k, j).Range.Text = "0"
      Next
    End With
  Next
End With
End Sub