Header/Footer lost with InsertFile

[cksm4]

Hello all,



Using the below code starting in a section where the Header/Footer is linked to the previous section is removing the link and causing the page numbering to delete. Is there a way to modify this code to link to Header and Footer to the previous section after each file is inserted? I cannot figure out how to get '.HeaderFooter.LinkToPrevious' to work. Any ideas?

 
ChDir ActiveDocument.Path
myName = Dir("03*.doc*")
While myName <> ""
    With Selection
        .InsertFile FileName:=myName, ConfirmConversions:=False
        .InsertBreak Type:=wdSectionBreakNextPage
        .Collapse Direction:=wdCollapseEnd
    End With
    myName = Dir()
Wend

Thanks!
Brock

[macropod]

Hi Brock,

Using your code, I am only able to replicate the problem you describe if source document has its Section breaks. In such cases, you might choose to delete those Section breaks or change their formatting to 'same as previous'. As an example of the latter:

Sub Demo()
Dim myName As String, RngTmp As Range, Sctn As Section, HdFt As HeaderFooter
ChDir ActiveDocument.Path
myName = Dir("03*.doc*")
While myName <> ""
  With Selection
    Set RngTmp = .Range
    With RngTmp
      .Start = .Start - 1
      .End = .End + 1
    End With
    .InsertBreak Type:=wdSectionBreakNextPage
    .InsertFile FileName:="myName", ConfirmConversions:=False
    .InsertBreak Type:=wdSectionBreakNextPage
    With RngTmp
      For Each Sctn In .Sections
        With Sctn
          For Each HdFt In .Headers
            HdFt.LinkToPrevious = True
          Next HdFt
          For Each HdFt In .Footers
            HdFt.LinkToPrevious = True
          Next HdFt
        End With
      Next Sctn
    End With
  End With
  myName = Dir()
Wend
Set RngTmp = Nothing
End Sub

[cksm4]

Hey Paul,

Yes, you were exactly right! The section break was hidden in a table. Much appreciated as I know this took extra time to diagnose. I also appreciate the code on linking the headers and footers... It works very well and accomplishes what I need. Thanks again!

Brock