Header/Footer lost with InsertFile

cksm4 · #1 03-02-2011, 05:14 PM

Hello all,

Using the below code starting in a section where the Header/Footer is linked to the previous section is removing the link and causing the page numbering to delete. Is there a way to modify this code to link to Header and Footer to the previous section after each file is inserted? I cannot figure out how to get '.HeaderFooter.LinkToPrevious' to work. Any ideas?

Code:

 
ChDir ActiveDocument.Path
myName = Dir("03*.doc*")
While myName <> ""
    With Selection
        .InsertFile FileName:=myName, ConfirmConversions:=False
        .InsertBreak Type:=wdSectionBreakNextPage
        .Collapse Direction:=wdCollapseEnd
    End With
    myName = Dir()
Wend

Thanks!
Brock

macropod · #2 03-04-2011, 08:44 PM

Hi Brock,

Using your code, I am only able to replicate the problem you describe if source document has its Section breaks. In such cases, you might choose to delete those Section breaks or change their formatting to 'same as previous'. As an example of the latter:

Code:

Sub Demo()
Dim myName As String, RngTmp As Range, Sctn As Section, HdFt As HeaderFooter
ChDir ActiveDocument.Path
myName = Dir("03*.doc*")
While myName <> ""
  With Selection
    Set RngTmp = .Range
    With RngTmp
      .Start = .Start - 1
      .End = .End + 1
    End With
    .InsertBreak Type:=wdSectionBreakNextPage
    .InsertFile FileName:="myName", ConfirmConversions:=False
    .InsertBreak Type:=wdSectionBreakNextPage
    With RngTmp
      For Each Sctn In .Sections
        With Sctn
          For Each HdFt In .Headers
            HdFt.LinkToPrevious = True
          Next HdFt
          For Each HdFt In .Footers
            HdFt.LinkToPrevious = True
          Next HdFt
        End With
      Next Sctn
    End With
  End With
  myName = Dir()
Wend
Set RngTmp = Nothing
End Sub

cksm4 · #3 03-07-2011, 06:09 PM

Hey Paul,

Yes, you were exactly right! The section break was hidden in a table. Much appreciated as I know this took extra time to diagnose. I also appreciate the code on linking the headers and footers... It works very well and accomplishes what I need. Thanks again!

Brock

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Header & Footer Question - Help Need!	Valentino.R	Word	9	11-29-2010 08:23 AM
Different Header but same Footer	Karthick	Word	1	11-12-2010 09:08 AM
How do I remove header and footer	captn1	Word	2	09-04-2010 04:14 PM
header/footer question	Bobosmite	Word	4	06-14-2010 07:22 AM
Header and footer questions	boutells	Word	0	07-21-2009 01:57 AM