Sub Demo()
Application.ScreenUpdating = False
Dim i As Long, j As Long, StrBkMk As String
Dim StrNoChr As String: StrNoChr = """‘'’“”*!.,/\:;?|{}[]()&" & vbCr & Chr(11) & Chr(12) & vbTab
With ActiveDocument.Range
  For i = .Bookmarks.Count To 1 Step -1
    With .Bookmarks(i)
      If Left(.Name, 1) = "_" Then If Right(.Name, 3) Like "###" Then .Delete
    End With
  Next
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = ""
    .Replacement.Text = ""
    .Style = "myStyle"
    .Forward = True
    .Wrap = wdFindStop
    .Format = True
  End With
  Do While .Find.Execute
    StrBkMk = Replace(Trim(.Text), " ", "_")
    For j = 1 To Len(StrNoChr): StrBkMk = Replace(StrBkMk, Mid(StrNoChr, j, 1), ""): Next
    i = i + 1: .Bookmarks.Add "_" & Left(StrBkMk, 36) & Format(i, "000"): .Collapse wdCollapseEnd
    If .Information(wdWithInTable) = True Then
      If .End = .Cells(1).Range.End - 1 Then
        .End = .Cells(1).Range.End
        .Collapse wdCollapseEnd
        If .Information(wdAtEndOfRowMarker) = True Then
          .End = .End + 1
        End If
      End If
    End If
    .Collapse wdCollapseEnd
    If (ActiveDocument.Range.End - .End) < 2 Then Exit Do
  Loop
End With
Application.ScreenUpdating = True
MsgBox i & " bookmarks added."
End Sub

Sub AddBookmarksMyStyle()
  Dim aRng As Range, sBk As String
  Set aRng = ActiveDocument.Range

  With aRng.Find
    .ClearFormatting
    .Style = ActiveDocument.Styles("myStyle")
    .Replacement.ClearFormatting
    .Text = ""
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchKashida = False
    .MatchDiacritics = False
    .MatchAlefHamza = False
    .MatchControl = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    Do While .Execute = True
      sBk = MakeValidBookmarkName(aRng.Text)
      ActiveDocument.Bookmarks.Add Name:=sBk, Range:=aRng
      aRng.Collapse Direction:=wdCollapseEnd
    Loop
  End With
End Sub

'---------------------------------------------------------
Function MakeValidBookmarkName(ByVal inputName As String) As String
  Dim regex As Object
  Set regex = CreateObject("VBScript.RegExp")
  regex.Pattern = "[^a-zA-Z0-9_]"  ' Define pattern to match invalid characters (anything not alphanumeric or underscore)
  regex.Global = True
  MakeValidBookmarkName = regex.Replace(inputName, "_")  ' Replace invalid characters with underscore
  If IsNumeric(Left(MakeValidBookmarkName, 1)) Then  ' Solve if name starts with number
    MakeValidBookmarkName = "BM_" & MakeValidBookmarkName
  End If
End Function