Macro to apply border color

RobiNew · #1 04-12-2025, 09:11 AM

Could someone suggest a shorter code for this macro? Thanks!

Code:

Sub BorderColor()
MyColor = InputBox("Specify color code", "Border Color")
    With Selection.ParagraphFormat
        With .Borders(wdBorderLeft)
            .LineStyle = wdLineStyleSingle
            .LineWidth = wdLineWidth050pt
            .Color = MyColor
        End With
        With .Borders(wdBorderRight)
            .LineStyle = wdLineStyleSingle
            .LineWidth = wdLineWidth050pt
            .Color = MyColor
        End With
        With .Borders(wdBorderTop)
            .LineStyle = wdLineStyleSingle
            .LineWidth = wdLineWidth050pt
            .Color = MyColor
        End With
        With .Borders(wdBorderBottom)
            .LineStyle = wdLineStyleSingle
            .LineWidth = wdLineWidth050pt
            .Color = MyColor
        End With
        With .Borders
            .DistanceFromTop = 1
            .DistanceFromLeft = 4
            .DistanceFromBottom = 1
            .DistanceFromRight = 4
            .Shadow = False
        End With
    End With
    With Options
        .DefaultBorderLineStyle = wdLineStyleSingle
        .DefaultBorderLineWidth = wdLineWidth050pt
        .DefaultBorderColor = MyColor
    End With
End Sub

vivka · #2 04-12-2025, 11:20 AM

Hi, RobiNew! Please, try this one:

Code:

Sub BorderColor()

Dim oBrdr As Variant
Dim MyColor As Long
    
    Application.ScreenUpdating = False
    MyColor = InputBox("Specify color code", "Border Color")

    For Each oBrdr In Array(wdBorderLeft, wdBorderRight, wdBorderTop, wdBorderBottom)
        With Selection.ParagraphFormat.Borders(oBrdr)
            .LineStyle = wdLineStyleSingle
            .LineWidth = wdLineWidth050pt
            .Color = MyColor
        End With
    Next oBrdr
    Application.ScreenUpdating = True
End Sub

It is shorter but not faster. Besides, you may face an issue entering a color code.

RobiNew · #3 04-13-2025, 12:06 AM

Hi, Vivka! Thank you for your assistance.

I get this error when I enter the color code:
Run-time Error '6': Overflow (The color code is 10027008)

Any idea? All the best, RobiNew

gmaxey · #4 04-13-2025, 05:32 AM

I didn't get your error running Vikka's code. You can also try:

Code:

Sub BorderColor()
Dim oBrdr As Variant
Dim MyColor As Long
    Application.ScreenUpdating = False
    MyColor = 10027008 'InputBox("Specify color code", "Border Color")
    For Each oBrdr In Selection.ParagraphFormat.Borders
      With oBrdr
        .LineStyle = wdLineStyleSingle
        .LineWidth = wdLineWidth050pt
        .Color = MyColor
      End With
    Next oBrdr
   Application.ScreenUpdating = True
End Sub

RobiNew · #5 04-13-2025, 07:30 AM

This one works also for me. Thanks, Greg! Thanks Vivka!

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Can't change border color of Office windows	coffent	Office	0	12-17-2020 09:21 AM
Word 16/19 change font and outside border color (same color) eg is red change to pink	jec1	Word VBA	2	12-04-2019 11:32 PM
VBA Word - Format ALL Tables - Apply Specific Formatting to Sets of Columns – Font, Border & Width	jc491	Word VBA	10	11-04-2015 04:02 PM
How to change the color of Character Border?	tinfanide	Word	4	10-27-2012 06:35 AM
Apply font color programatically using VBA Word	divakarganta	Word VBA	3	08-08-2012 08:05 PM