VBA Format Footnote Text Numbering

[Shelley Lou]

I recorded the code below using Find and Replace but I have to have the cursor placed directly in the footnote text. The code below formats the Footnote Text Numbering from 10pt Superscript to 8pt. Normal Text.



Is there a better way I could perform this action to do the formatting automatically when running the code?

Before
Before.JPG

After
After.JPG

Sub Test1_FormatFootnoteNumber()
Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
With Selection.Find.Replacement.Font
.Size = 8
.Italic = False
.Bold = True
.Superscript = False
.Subscript = False
End With
With Selection.Find
.text = "^f"
.Replacement.text = "^&"
.Forward = True
.Wrap = wdFindContinue
.Format = True
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
End Sub

[Guessed]

The number is formatted with the Footnote Reference character style. I would just modify that style to hit them all at once. However, that same character style is also used where the footnote ref appears in the body of the document so you would also be changing those instances as well.

Perhaps search in the Footnotes story and replace that style with an alternate character style that has the attributes you want.

Sub RestyleFootnoteNums()
  Dim aRng As Range
  Set aRng = ActiveDocument.StoryRanges(wdFootnotesStory)
  With aRng.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = ""
    .Style = "Footnote Reference"   'find this style
    .Replacement.Style = "Emphasis"   'replace with this style
    .Execute Replace:=wdReplaceAll
  End With
End Sub

[Shelley Lou]

Hi Andrew, thank you so much for replying. I couldn't get your code to work but after refining various find and replaced, the code below seems to work. Thank you so much for your time though, it was the wdFootnotesStory I didn't think of.

Sub FormatFootnoteNumber()
Application.ScreenUpdating = False
With ActiveDocument.StoryRanges(wdFootnotesStory).Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .text = "^2"
    .Replacement.text = "^&"
    .Replacement.Font.Superscript = False
    .Replacement.Font.Size = 8
    .Replacement.Font.Bold = True
    .Forward = True
    .Format = True
    .Wrap = wdFindContinue
    .Execute Replace:=wdReplaceAll
End With
Application.ScreenUpdating = True
End Sub