Height of all rows of all tables set as "at least".

woocash_11 · #1 03-17-2024, 01:37 AM

Hi guys,

as in the title, I need a VBA code that sets height of all rows in all tables in document as "at least" but without changing the value of the height, so when the volume of text in the cell increases, the cell expands, but when it decreases the cell DOES NOT shrink.

I would appreciate any help

vivka · #2 03-17-2024, 01:54 AM

Hi, Woocash_11! Try this:

Code:

Sub Tbls_Format_1()
'Format all tables in active doc.

Dim oTbl As word.Table
    For Each oTbl In ActiveDocument.Tables
        oTbl.rows.HeightRule = wdRowHeightAtLeast   
    Next oTbl
End Sub

woocash_11 · #3 03-17-2024, 02:12 AM

Hi vivka, thank you for this!

However I already tried something very similar and this one works exactly the same - it does change the parameter "exactly" to "at least", but it somehow changes the value of all rows to the value from the first row of first table in the document, and unfortunately it makes it unusable

I also tried asking AI, but apparently those I asked didn't work with VBA codes very well

gmaxey · #4 03-17-2024, 05:26 AM

Code:

Sub Tbls_Format_1()
Dim oRow As Row
Dim oTbl As Word.Table
  For Each oTbl In ActiveDocument.Tables
    For Each oRow In oTbl.Rows
       oRow.HeightRule = wdRowHeightAtLeast
    Next oRow
  Next oTbl
lbl_Exit:
  Exit Sub
End Sub

woocash_11 · #5 03-17-2024, 08:52 AM

Thanks gmaxey.

Maybe this would work if the tables are basic. Unfortunatelly it doesn't work when there are tables with vertically merged cells.

Italophile · #6 03-17-2024, 09:05 AM

Unless the height of the rows has already been set to "At Least", or "Exactly", there is no way to determine the current height of the row. Querying the row height in VBA will return a value of "Undefined".

You will need to decide what the minimum height should be, then modify the code in post #2 to set the Height property

woocash_11 · #7 03-17-2024, 09:35 AM

Quote:

Originally Posted by Italophile

Unless the height of the rows has already been set to "At Least", or "Exactly", there is no way to determine the current height of the row. Querying the row height in VBA will return a value of "Undefined".

You will need to decide what the minimum height should be, then modify the code in post #2 to set the Height property

You know, the problem is I am OCR specialist and my software always defines table row height as "exactly". These heights vary depending on the table and I can't define the minimum height.

In my work computer there were the script on the outside platform that was doing this without any problems, so I thought it might be possible via VBA code. Apparently I was wrong

Italophile · #8 03-18-2024, 03:05 AM

Quote:

Originally Posted by woocash_11

In my work computer there were the script on the outside platform that was doing this without any problems, so I thought it might be possible via VBA code. Apparently I was wrong

It is possible via VBA code, but you need to answer the same question as in the UI - at least what?

This is a decision that is usually taken at the time of designing the document, not applied after the fact when you already have tables with content and merged cells.

Guessed · #9 03-18-2024, 03:07 PM

Try this version

Code:

Sub TableRowAtLeast()
  Dim iSize As Long, aCell As Cell, aTbl As Table
  For Each aTbl In ActiveDocument.Tables
    For Each aCell In aTbl.Range.Cells
      If aCell.HeightRule = wdRowHeightExactly Then
        iSize = aCell.Height
        aCell.HeightRule = wdRowHeightAtLeast
        aCell.Height = iSize
      End If
    Next aCell
  Next aTbl
End Sub

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Excel 2003: VBA "Function" causes "#VALUE!" errors after running "insert/delete row" custom macro	Matt C	Excel Programming	2	01-08-2022 06:03 AM
Help get rid of weird default "lines" or "table" look in document that has no tables or lines	Tsavard	Word	2	06-11-2018 09:08 AM
Macro to delete all rows with the word "Total"	RandWald	Excel Programming	4	11-28-2016 07:50 PM
Word Macro to find and delete rows that contain adjacent cells containing "."	AlexanderJohnWilley	Word VBA	7	11-08-2012 10:15 AM
How to choose a "List" for certain "Heading" from "Modify" tool?	Jamal NUMAN	Word	2	07-03-2011 03:11 AM