Find Names in Word document

landrob1 · #1 01-19-2024, 06:11 AM

Hello everyone,

I am new here and quite inexperienced with such topics. I'm generally comfortable with Word, but I've run into the problem that I haven't formatted the last names of the authors correctly in a longer scientific paper. Now I need some help. Is there a way, a chatgpt integration, VBA etc., to find names in a Word document and then reformat them?

Thanks for the help and sorry for my probably naive question, best regards
Landro

vivka · #2 01-19-2024, 07:45 AM

Hi! A general answer to a general question: yes, there's a way to find and format names in Word. What's next? Sorry, but you are not specific. What do you mean by "name" and how are you going to reformat the found names?

landrob1 · #3 01-19-2024, 07:48 AM

Hi Vivika,

thanks for the reply.

My aim would be to set all the author references in small caps (in italics if necessary) for a Word document that has approx. 300 pages - and if possible automatically, so that I don't have to enter them individually. What would be necessary for this? Or what would be the most elegant way?

I hope this is more specific. Thanks in advance

vivka · #4 01-19-2024, 07:50 AM

Could you post at least one reference with name(s). A macro (quite simple) would find words started with a capital letter & change them to all caps. Problem: if a word that is not a name starts a sentence can also be treated as a name. The macro should need more signs of a name to exclude false hits. That's why your sample would be helpful.

landrob1 · #5 01-19-2024, 07:52 AM

Sure thing. It's in german:
"vgl. Schlögl, Rudolf: Politik beobachten. Öffentlichkeit und Medien in der Frühen Neuzeit, in: Zeitschrift für historische Forschung (35), 2008, S. 581–616".
But also:
"Vgl. Bernsee (2017), S. 172."

vivka · #6 01-19-2024, 07:59 AM

Good! It's much better! So, every surname follows 'Vgl. '. This simplifies the task. Wait a little for the code.

vivka · #7 01-19-2024, 08:50 AM

Landrob1, here you are:

Code:

Sub Authors()
'Format all surnames (found according to their specific signs) in the selected range.

Dim rng As range
    Application.ScreenUpdating = False
    Set rng = selection.range
    With rng.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .text = "[Vv]gl. <[A-Z][!A-Z][a-z]@>"
        .Forward = True
        .MatchWildcards = True
        .Wrap = wdFindStop
        While .Execute
            rng.MoveStart unit:=wdCharacter, count:=5
            rng.Font.Italic = True
            rng.Font.AllCaps = True
            rng.Collapse wdCollapseEnd
        Wend
    End With
    Application.ScreenUpdating = True
    Set rng = Nothing
 End Sub

Note that the macro works on the selected range. As to me, it's more flexible than 'ActiveDocument.range'. A tip: to select a whole doc, press Ctrl+A.

landrob1 · #8 01-19-2024, 08:59 AM

Thx a lot! I will give it a try.

vivka · #9 01-19-2024, 09:01 AM

I've tested it, but no one is perfect.

landrob1 · #10 01-20-2024, 08:19 AM

Hello again,
worked wonderfully, but does not help in every case, which was clear

What would a code look like that searches for names from a provided in a Word document and then sets them in small caps.
So if I have the following names:
Ackermann
Angermann
Andersen
Atzeni
Baecker
Ortmann
...
What would that look like?
Many thanks in advance!

vivka · #11 01-20-2024, 09:21 AM

Hi! I've changed one line for small caps:

Code:

Sub Authors()
'Format all surnames (found according to their specific signs) in the selected range.

Dim rng As range
    Application.ScreenUpdating = False
    Set rng = selection.range
    With rng.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .text = "[Vv]gl. <[A-Z][!A-Z][a-z]@>"
        .Forward = True
        .MatchWildcards = True
        .Wrap = wdFindStop
        While .Execute
            rng.MoveStart unit:=wdCharacter, count:=5
            rng.Font.Italic = True
            rng.Font.SmallCaps = True
            rng.Collapse wdCollapseEnd
        Wend
    End With
    Application.ScreenUpdating = True
    Set rng = Nothing
 End Sub

The code woarks for all names (including those in the list) if they are preceded by 'V/vgl. '. If you have a problem, please, post a sample. I can suggest that there's more than one space before the "faulty" surnames.

landrob1 · #12 01-20-2024, 09:26 AM

Hey, thanks!
But I think I expressed myself in a misleading way. I was referring to a different code. It should search for all names in a list in the corresponding Word document and then set them in small caps. I hope that's clearer now ...
I would have tried the following, but it doesn't work.

THX!!!

Sub FormatAuthorNamesInSmallCaps()
Dim authorNames As Variant
Dim rng As Range
Dim name As Variant

' Liste der Autorennamen
authorNames = Array("Ackermann", "Angermann", "Andersen", "Atzeni", "Baecker", "Ortmann", "Zamoyski", "Ziegler", "Wurzbach", "Zittel", "Zürcher", "Zytphen-Adeler")

Application.ScreenUpdating = False
Set rng = ActiveDocument.Range

For Each name In authorNames
With rng.Find
.ClearFormatting
.Replacement.ClearFormatting
.Text = name
.Replacement.Text = name
.Forward = True
.Wrap = wdFindContinue
.Execute Replace:=wdReplaceAll
If .Found Then
rng.Font.SmallCaps = True
End If
End With
rng.SetRange Start:=ActiveDocument.Range.Start, _
End:=ActiveDocument.Range.End
Next name

Application.ScreenUpdating = True
End Sub

vivka · #13 01-20-2024, 10:05 AM

This seems to work:

Code:

Sub FormatAuthorNamesInSmallCaps()

Dim rng As range
Dim authorNames As Variant

Application.ScreenUpdating = False
    Set rng = ActiveDocument.range

'Liste der Autorennamen
    authorNames = Array("Ackermann", "Angermann", _
    "Andersen", "Atzeni", "Baecker", "Ortmann", _
    "Zamoyski", "Ziegler", "Wurzbach", "Zittel", _
    "Zürcher", "Zytphen-Adeler")

    For i = 0 To UBound(authorNames)
        With rng.Find
            .ClearFormatting
            .Replacement.ClearFormatting
            .text = authorNames(i)
            .Forward = True
            .Wrap = wdFindStop
            .MatchWholeWord = True
            While .Execute
                rng.Font.Italic = True
                rng.Font.SmallCaps = True
                rng.Collapse wdCollapseEnd
            Wend
        End With
    Next i
Application.ScreenUpdating = True
End Sub

landrob1 · #14 01-20-2024, 10:11 AM

Quote:

Originally Posted by vivka

This seems to work:

Code:

Sub FormatAuthorNamesInSmallCaps()

Dim rng As range
Dim authorNames As Variant

Application.ScreenUpdating = False
    Set rng = ActiveDocument.range

'Liste der Autorennamen
    authorNames = Array("Ackermann", "Angermann", _
    "Andersen", "Atzeni", "Baecker", "Ortmann", _
    "Zamoyski", "Ziegler", "Wurzbach", "Zittel", _
    "Zürcher", "Zytphen-Adeler")

    For i = 0 To UBound(authorNames)
        With rng.Find
            .ClearFormatting
            .Replacement.ClearFormatting
            .text = authorNames(i)
            .Forward = True
            .Wrap = wdFindStop
            .MatchWholeWord = True
            While .Execute
                rng.Font.Italic = True
                rng.Font.SmallCaps = True
                rng.Collapse wdCollapseEnd
            Wend
        End With
    Next i
Application.ScreenUpdating = True
End Sub

Thx a lot!!!!

vivka · #15 01-20-2024, 10:24 AM

You are welcome!

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Printing list of names in a publisher or word document	Marcia	Word	2	09-27-2018 01:28 AM
How to find CAPITALIZED names and change them into small caps	dylan.ve	Word VBA	5	02-25-2016 03:15 PM
Find and replace inside strings containing various names	audioman	Word VBA	4	03-25-2014 11:19 AM
Word Form / VBA Solution for Formatted Document	elmousa68	Word VBA	5	10-15-2013 05:10 PM
find author names in text	anil3b2	Word	0	08-02-2010 04:12 AM