Refer to second table in document

[George24]

Hi,




I have a Word document with 2 tables. The macro I want to run should only apply to the second table. How do I do this? Please explain like I'm 5?

Sub DeleteEmptyRows()
Dim tbl As Table, cel As Cell
Dim i As Long, j As Long, n As Long, fEmpty As Boolean
Application.ScreenUpdating = False
With ActiveDocument
For Each tbl In .Tables
n = tbl.Rows.Count
For i = n To 1 Step -1
fEmpty = True
For j = 3 To tbl.Rows(i).Cells.Count
Set cel = tbl.Rows(i).Cells(j)
If Len(cel.Range.Text) > 2 Then
fEmpty = False
Exit For
End If
Next j
If fEmpty = True Then tbl.Rows(i).Delete
Next i
Next tbl
End With
Set cel = Nothing: Set tbl = Nothing
Application.ScreenUpdating = True
End Sub

[vivka]

Hi! Try this:

Sub DeleteEmptyRows_If()
'In the doc's 2nd tbl, delete rows if any of their cells starting from the 3rd cell is empty.

Dim tbl As Table, cel As cell
Dim i As Long, j As Long, n As Long

    Application.ScreenUpdating = False
    Set tbl = ActiveDocument.range.Tables(2)
    n = tbl.rows.count
    For i = n To 1 Step -1
        For j = 3 To tbl.rows(i).Cells.count
            Set cel = tbl.rows(i).Cells(j)
            If Len(cel.range.text) = 2 Then
                 tbl.rows(i).Delete
                Exit For
             End If
        Next j
    Next i
Set cel = Nothing: Set tbl = Nothing
Application.ScreenUpdating = True
End Sub

[George24]

Hey,


Thank you for responding!

Unfortunately it didn't work it returns an error on a specific line. I tried implementing your code "Set tbl = ActiveDocument.Range.Tables(2)" in my macro, but this one didn't work either. Do you know if there's another way to refer back to the second table on my document?

[vivka]

Try copy-pasting the updated code again. I've checked it and it runs smoothly. I've imroved the code: now you can select the table and cell to start from:

Sub Del_Empty_Rows_If_3()
'In the doc's n-th tbl, delete rows if any (at least one) of their cell
'starting from the 3rd cell is empty.

Dim tbl As Table, tblNo As Long, cel As cell, cellNo As Long
Dim i As Long, j As Long, n As Long

    Application.ScreenUpdating = False
    tblNo = InputBox("Enter the table's number:")
    If tblNo > ActiveDocument.range.Tables.count Then
        MsgBox "There's no table with this number in this document."
        Exit Sub
    End If
    Set tbl = ActiveDocument.range.Tables(tblNo)
    cellNo = InputBox("Enter the cell's number to start from:")
    n = tbl.rows.count
    For i = n To 1 Step -1
        For j = cellNo To tbl.rows(i).Cells.count
            Set cel = tbl.rows(i).Cells(j)
            If Len(cel.range.text) = 2 Then
                tbl.rows(i).Delete
                Exit For
            End If
        Next j
    Next i
Set cel = Nothing: Set tbl = Nothing
Application.ScreenUpdating = True
End Sub

[George24]

The last one did the trick, thank you so much!!!!

[vivka]

You are welcome, George24 and kind lurkers!