Find a word and then check if its paragraph is a list pargraph or not

[RobiNew]

I'm tryng to check if a paragraph containg the 'Found' word is a list paragraph or not. Can someone help with the tentative code here below? Thanks!

Sub ListOrNot()
Dim aRng As Range
Set aRng = ActiveDocument.Range
    With aRng.Find
      .ClearFormatting
      .Replacement.ClearFormatting
      .Wrap = wdFindStop
      .Format = False
      .MatchCase = False
      .MatchWildcards = False
      .Text = "Title"
      .Execute
    End With
check = aRng.Find.Found.ListFormat.ListType
MsgBox check
End Sub

[vivka]

Hi, RobiNew! This works for me:

Sub ListOrNot()
Dim aRng As range
Set aRng = ActiveDocument.range
    With aRng.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Wrap = wdFindStop
        .Format = False
        .MatchCase = False
        .MatchWildcards = False
        .text = "Title"
        If .Execute Then
            aRng.Select
            check = aRng.Paragraphs(1).range.ListFormat.ListType
            If check <> 0 Then
                MsgBox "This is a list paragraph"
            Else
                MsgBox "This is not a list paragraph"
            End If
        End If
     End With
  Set aRng = Nothing
End Sub

[gmaxey]

Vivka, RobiNew


Check is superfluous. If it wasn't, it isn't declared. If you declare variables, declare them all.

Sub ListOrNot()
Dim aRng As Range
Set aRng = ActiveDocument.Range
  With aRng.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Wrap = wdFindStop
    .Format = False
    .MatchCase = False
    .MatchWildcards = False
    .Text = "Title"
    If .Execute Then
      If aRng.Paragraphs(1).Range.ListFormat.ListType <> 0 Then
        MsgBox "This is a list paragraph"
      Else
        MsgBox "This is not a list paragraph"
      End If
    End If
   End With
  Set aRng = Nothing
End Sub

[vivka]

Yes, Greg, you are right! Thank you for your correction!

[RobiNew]

Many thanks to you both! À la prochaine!