Option Explicit

Sub ReplaceHeaderandInsertLogo()

    ' Turn off screen updating
    Application.ScreenUpdating = False

    Dim oDoc As Document
    Dim oSec As Section
    Dim oHead As HeaderFooter
    Dim oRng As Range
    Dim oShape As InlineShape

    ' Define the locations of the logos
    Dim strLogoFrontpage As String
    Dim strLogoSubsequentPages As String
    strLogoFrontpage = "C:\Test\logo_frontpage.jpg"
    strLogoSubsequentPages = "C:\Test\logo_subsequentpages.png"

    ' Set the active document
    Set oDoc = ActiveDocument

    ' Loop through each section in the document
    For Each oSec In oDoc.Sections

        ' Set the first page to have a different header/footer (applies to the entire document)
        oSec.PageSetup.DifferentFirstPageHeaderFooter = True

        ' Loop through each header in the section
        For Each oHead In oSec.Headers
            If oHead.Exists Then
                Set oRng = oHead.Range
                With oRng
                    .Text = Chr(13) ' Reset the header text
                    .Collapse 0
                    .ParagraphFormat.alignment = wdAlignParagraphCenter ' Center align the content

                    ' Check if the current header is for the first page or subsequent pages
                    If oHead.index = wdHeaderFooterFirstPage Then
                        Set oShape = .InlineShapes.AddPicture(FileName:=strLogoFrontpage)
                        oShape.LockAspectRatio = msoTrue
                        oShape.Width = CentimetersToPoints(3.94)
                        oShape.AlternativeText = "frontpage"
                    ElseIf oHead.index = wdHeaderFooterPrimary Then
                        Set oShape = .InlineShapes.AddPicture(FileName:=strLogoSubsequentPages)
                        oShape.LockAspectRatio = msoTrue
                        oShape.Width = CentimetersToPoints(0.73)
                        oShape.AlternativeText = "subsequent page"
                    End If
                End With
            End If
        Next oHead
        
    Next oSec

    ' Turn on screen updating
    Application.ScreenUpdating = True

lbl_Exit:
    Set oSec = Nothing
    Set oHead = Nothing
    Set oShape = Nothing
    Set oRng = Nothing
    Set oDoc = Nothing

End Sub