Sub Paras_Start_Change_1()
'Change the selected paras from Before to After:
'Before:
' <S1>Text
' <S2>Text
' <S3>Text
' <S4>Text
' <S5>Text

'After:
' <S1>Text
' <S1-S2>Text
' <S2-S3>Text
' <S3-S4>Text
' <S4-S5>Text

Dim oSel As range
Dim oPar As Paragraph

    Application.ScreenUpdating = False
    Set oSel = selection.range
    For i = selection.range.Paragraphs.count To 1 Step -1
        Set oPar = oSel.Paragraphs(i)
        oPar.range.Select
        selection.Collapse 1
        selection.MoveUp Unit:=wdParagraph, count:=1
        If selection.Start < oSel.Start Then Exit For
        selection.MoveRight Unit:=wdCharacter, count:=1
        selection.MoveEndUntil Cset:=">"
        selection.Copy
        selection.MoveDown Unit:=wdParagraph, count:=1
        selection.MoveRight Unit:=wdCharacter, count:=1
        selection.PasteAndFormat (wdFormatOriginalFormatting)
        selection.TypeText text:="-"
    Next i
    Application.ScreenUpdating = True
End Sub

Sub ScratchMacro()
'A basic Word Macro coded by Gregory K. Maxey
Dim lngIndex As Long
Dim oRng As Range
Dim oParRng As Range
Dim arrIndexParts() As String
Dim strRefIndex As String
  Set oRng = ActiveDocument.Range 'or selection range
  For lngIndex = 1 To oRng.Paragraphs.Count - 1
    'See if the paragraph and subsequent paragraph have the indexing flag.
    If InStr(oRng.Paragraphs(lngIndex).Range.Text, "<S") = 1 And InStr(oRng.Paragraphs(lngIndex + 1).Range.Text, "<S") = 1 Then
      Set oParRng = oRng.Paragraphs(lngIndex).Range
      'Move the range until after the "<S"
      oParRng.MoveStart wdCharacter, 2
      'See if the paragraph is a simple or complex index e.g., "S1" or "S1-S2"
      If InStr(oParRng.Text, "-S") > 0 And InStr(oParRng.Text, "-S") < InStr(oParRng.Text, "> ") Then
        'Complex, move range passed the second index flag.
        oParRng.MoveStartUntil Cset:="S"
        oParRng.MoveStart wdCharacter, 1
        'Get the index number.
        arrIndexParts = Split(oParRng.Text, "> ")
        strRefIndex = arrIndexParts(0)
      Else
        'Get the index number
        arrIndexParts = Split(oParRng.Text, "> ")
        strRefIndex = arrIndexParts(0)
      End If
      'Get the subsequent paragraph index number and compare to previous
      Set oParRng = oRng.Paragraphs(lngIndex + 1).Range
      oParRng.MoveStart wdCharacter, 2
      arrIndexParts = Split(oParRng.Text, "> ")
      If strRefIndex + 1 = arrIndexParts(0) Then
        'Condition met.  Create complex index.
        oParRng.InsertBefore strRefIndex & "-S"
      End If
    End If
  Next lngIndex
lbl_Exit:
  Exit Sub
End Sub

Sub Paras_Start_Change_1()
'Modified by GKM
Dim lngIndex 'Declare variable for indexing.
Dim oSel As Range
Dim oPar As Paragraph
Dim bSCP As Boolean 'Added variable to store user setting.
  Application.ScreenUpdating = False
  'Save user setting
  bSCP = Options.PasteSmartCutPaste
  'Turn off smart cut and paste
  Options.PasteSmartCutPaste = False
  Set oSel = Selection.Range
  'Change .Count to 1 to .Count to 2
  For lngIndex = Selection.Range.Paragraphs.Count To 2 Step -1
    Set oPar = oSel.Paragraphs(lngIndex)
    oPar.Range.Select
    With Selection
      .Collapse 1
      .MoveUp Unit:=wdParagraph, Count:=1
      .MoveRight Unit:=wdCharacter, Count:=1
      .MoveEndUntil Cset:=">"
      .Copy
      .MoveDown Unit:=wdParagraph, Count:=1
      .MoveRight Unit:=wdCharacter, Count:=1
      .PasteAndFormat (wdFormatOriginalFormatting)
      .TypeText Text:="-"
    End With
  Next lngIndex
  'Restore user setting.
  Options.PasteSmartCutPaste = bSCP
  Application.ScreenUpdating = True
End Sub