VBA Code to remove specific highlight

syl3786 · #1 03-27-2023, 06:09 AM

Hi Community,

This is a macro for removing specific highlight in Word Documents. When you place the cursor at the highlighted text (e.g., it highlighted wdYellow), then ran the macro, it can remove all wdYellow highlights in that word document.

However, I found a bug in the "Removeonehighlight" macro. When there are words highlighted with two colors and connected each other like 123456, the macro cannot remove the highlight color, neither red or yellow one. (see the attached word file)

The code are as follows:

Code:

Sub Removeonehighlight()

    Dim HLColor As WdColorIndex
    Dim rg As Range

    HLColor = Selection.Range.HighlightColorIndex
    If HLColor <> wdNoHighlight Then
    
        Set rg = ActiveDocument.Range
        
        With rg.Find
            .Highlight = HLColor
            .Wrap = wdFindStop
            
            While .Execute
                If rg.HighlightColorIndex = HLColor Then
                    rg.HighlightColorIndex = wdNoHighlight
                End If
                rg.Collapse wdCollapseEnd
            Wend
            
        End With
        
    Else

        MsgBox "Please place you cursor on the highlight color you want to remove."
    End If
        
End Sub

And I tried many other macros for removing specific highlight colours but in vain. All of them encounter the same issue. Does any experts know how to edit the above codes so that I can use it to remove highlight colors, even though a text was highlighted in two colours?

Your help would be greatly appreciated!

gmaxey · #2 03-27-2023, 06:55 AM

Code:

Sub ScratchMacro()
'A basic Word Macro coded by Gregory K. Maxey
Dim oRng As Range
  Set oRng = ActiveDocument.Range
  With oRng.Find
    .Highlight = True
    While .Execute
      Select Case oRng.HighlightColorIndex
        Case Is = 9999999
          oRng.HighlightColorIndex = wdAuto
      End Select
      oRng.Collapse wdCollapseEnd
    Wend
  End With
lbl_Exit:
  Exit Sub
End Sub

syl3786 · #3 03-27-2023, 08:21 AM

Quote:

Originally Posted by gmaxey

Code:

Sub ScratchMacro()
'A basic Word Macro coded by Gregory K. Maxey
Dim oRng As Range
  Set oRng = ActiveDocument.Range
  With oRng.Find
    .Highlight = True
    While .Execute
      Select Case oRng.HighlightColorIndex
        Case Is = 9999999
          oRng.HighlightColorIndex = wdAuto
      End Select
      oRng.Collapse wdCollapseEnd
    Wend
  End With
lbl_Exit:
  Exit Sub
End Sub

Thank you gmaxey! It is very useful. MayI ask if this macro can just remove the one of the selected highlight colours but not remove all of them? Now it just remove texts with two highlighted colors combined and remove those combination.

gmaxey · #4 03-27-2023, 08:57 AM

First, while a common mistake, I am not Gmayor.

If you want to get rid of red highlighting in a mix of red and some other color:

Code:

Sub ScratchMacro()
'A basic Word Macro coded by Gregory K. Maxey
Dim oRng As Range
Dim oChr As Range
  Set oRng = ActiveDocument.Range
  With oRng.Find
    .Highlight = True
    While .Execute
      Select Case oRng.HighlightColorIndex
        Case Is = 9999999
          For Each oChr In oRng.Characters
            If oChr.HighlightColorIndex = wdRed Then
              oChr.HighlightColorIndex = wdAuto
            End If
          Next
        Case Is = wdRed
          oRng.HighlightColorIndex = wdAuto
      End Select
      oRng.Collapse wdCollapseEnd
    Wend
  End With
lbl_Exit:
  Exit Sub
End Sub

or like this:

Code:

Sub ScratchMacro()
'A basic Word Macro coded by Gregory K. Maxey
Dim oRng As Range
Dim oChr As Range
  Set oRng = ActiveDocument.Range
  With oRng.Find
    .Text = "*"
    .MatchWildcards = True
    .Highlight = True
    While .Execute
      Select Case oRng.HighlightColorIndex
        Case Is = wdRed
          oRng.HighlightColorIndex = wdAuto
      End Select
      oRng.Collapse wdCollapseEnd
    Wend
  End With
lbl_Exit:
  Exit Sub
End Sub

syl3786 · #5 03-27-2023, 05:01 PM

Quote:

Originally Posted by gmaxey

First, while a common mistake, I am not Gmayor.

If you want to get rid of red highlighting in a mix of red and some other color:

Code:

Sub ScratchMacro()
'A basic Word Macro coded by Gregory K. Maxey
Dim oRng As Range
Dim oChr As Range
  Set oRng = ActiveDocument.Range
  With oRng.Find
    .Highlight = True
    While .Execute
      Select Case oRng.HighlightColorIndex
        Case Is = 9999999
          For Each oChr In oRng.Characters
            If oChr.HighlightColorIndex = wdRed Then
              oChr.HighlightColorIndex = wdAuto
            End If
          Next
        Case Is = wdRed
          oRng.HighlightColorIndex = wdAuto
      End Select
      oRng.Collapse wdCollapseEnd
    Wend
  End With
lbl_Exit:
  Exit Sub
End Sub

or like this:

Code:

Sub ScratchMacro()
'A basic Word Macro coded by Gregory K. Maxey
Dim oRng As Range
Dim oChr As Range
  Set oRng = ActiveDocument.Range
  With oRng.Find
    .Text = "*"
    .MatchWildcards = True
    .Highlight = True
    While .Execute
      Select Case oRng.HighlightColorIndex
        Case Is = wdRed
          oRng.HighlightColorIndex = wdAuto
      End Select
      oRng.Collapse wdCollapseEnd
    Wend
  End With
lbl_Exit:
  Exit Sub
End Sub

I deeply apologize for called the wrong name. I made a mistake. Thank you so much for your help! They works well!

Thread Tools
Show Printable Version Email this Page
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
VBA Highlight numbers only after or before specific words help	Shelley Lou	Word VBA	12	08-09-2022 03:02 AM
Remove highlight with specific color	rekent	Word VBA	2	08-01-2020 10:59 AM
How to highlight lines containing specific words	SixStringSW	Word VBA	4	06-03-2018 03:57 PM
VBA to highlight specific values in the spreadsheet	daiwuliz	Excel	6	05-23-2018 10:30 AM
Highlight the current cell without using code	parshla	Excel	0	09-08-2016 08:10 PM