Help making a Macro

[Mullin4414]

someone who is good a programing may be able to help me here, i am trying to set up a macro to mimic a medical software i use at work. basically anytime i press the F2 key in whatever word document i am in i want the macro to highlight the next set of "***" in my document so i can start typing and it will replace the 3 asterisk's

[gmayor]

You can record a macro that will do that. e.g.

Sub Macro1()
    Selection.HomeKey wdStory
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = "***"
        .Wrap = wdFindStop
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute
End Sub

It might make more sense to replace your asterisks with content controls e.g.

Sub Macro2()
Dim oRng As Range
Dim oCC As ContentControl
Dim i As Integer: i = 0
    Set oRng = ActiveDocument.Range
    With oRng.Find
        .Wrap = wdFindContinue
        Do While .Execute("***")
            i = i + 1
            oRng.Text = ""
            Set oCC = oRng.ContentControls.Add(wdContentControlRichText)
            oCC.Title = "Text" & i
            oCC.Tag = oCC.Title
            oCC.LockContentControl = True
            oRng.End = oRng.End + 1
            oRng.Collapse 0
        Loop
    End With
End Sub

[Mullin4414]

thank you so much this is going to help me a lot!, since you seem to be very quick with the code (i havent tried the second one yet im still working out how this all works), do you know if there is a way to instead of selecting the *** i could select the next group of lets say red text or bold text or whatever is easiest, so if i wrote "put patient name here" in red text i could hit F2 and have it select that group of text for me to replace?

[gmayor]

You can assign the following to a key -

Sub FindRed()
    Selection.Find.ClearFormatting
    Selection.Find.Font.Color = wdColorRed
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = ""
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute
End Sub

However it seems that you are trying to create proforma templates for documenting patients. That being the case I would recommend using Rich Text content controls and/or List Box content controls for selecting from lists. To that end you will probably find Insert Content Control Add-In useful. Although not essential for it to work, it is advisable to give the fields unique titles

You can also use that add-in to add 'editors' to the fields and protect the form as read only. You can then only enter text in the fields.

[Mullin4414]

I greatly appreciate you're help with all this!