Get the position of a string from the cursor position forward

alex100 · #1 02-21-2023, 12:18 PM

In a Word document, how can I get the position of a string from the cursor position forward?

For example, if the cursor is on the 10th line from the start of the document and the string I am trying to find is on the 15th line, the function should return 5.

If the string is found in multiple places throughout the document (both before and after the cursor), the function should return the position of the first match after the cursor. If it is found only before the cursor (or not found at all), the function should return a null value.

Thank you!

Alex

Guessed · #2 02-21-2023, 04:02 PM

Word's vba doesn't normally do well with 'lines' because the wrapping of lines is dynamic (reliant on typeface, size, column width, text wrapping etc) and not structural. Paragraphs are the units that we can code with reliably. So let's assume you meant paragraphs.

Code:

Sub FindAhead()
  Dim aRng As Range, sFind As String, iResp As Integer, lngStart As Long, lngFound As Long
  sFind = "Save time in Word"
  Set aRng = Selection.Range
  lngStart = aRng.Start
  aRng.End = ActiveDocument.Range.End
  With aRng.Find
    .ClearFormatting
    .Text = sFind
    .Forward = True
    If .Execute Then
      lngFound = ActiveDocument.Range(lngStart, aRng.Paragraphs(1).Range.End).Paragraphs.Count - 1
      iResp = MsgBox("Do you want to jump to the next found instance?", vbYesNo, lngFound & " paragraphs ahead")
      If iResp = vbYes Then aRng.Select
    Else
      MsgBox "Ain't no more", vbCritical + vbOKOnly, "None found"
    End If
  End With
End Sub

alex100 · #3 02-22-2023, 02:48 AM

Wonderful! Thank you, Andrew!

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
select the sentence at cursor position	ilcaa72	Word VBA	3	04-28-2017 05:42 AM
changing cursor position	anand	Word VBA	2	06-19-2015 05:18 AM
Increase Sentence Font at cursor position	ilcaa72	Word VBA	8	02-20-2014 08:40 AM
Displaying cursor position within cell	MiamiTom	Excel	0	11-18-2011 09:02 AM
Retrieve position of Cursor - x & y positions	SDondeti	PowerPoint	0	05-19-2011 11:39 AM