Macro to return a specific character in a specific paragraph.

[RobiNew]

I'm trying to devise a code to return a specific character in a specific paragraph. Can someone help? Thanks!

Sub ChrSix()
'The sixth character in the first word of paragraph 5 is "." (Title.)
  With ActiveDocument
 If .Paragraphs(5).Range.Words(1).Characters(6) = "." Then
MsgBox "Found"
 Else
MsgBox "Not Found"
End If
  End With
End Sub

[gmaxey]

The "." after Title is not the sixth character for the first word. It is the first characters of the second Word ". "

Sub ChrSix()
'The sixth character in the first word of paragraph 5 is "." (Title.)
  With ActiveDocument
 If .Paragraphs(5).Range.Words(2).Characters(1) = "." Then
MsgBox "Found"
 Else
MsgBox "Not Found"
End If
  End With
End Sub

See for yourself:
Sub ScratchMacro()
'A basic Word Macro coded by Gregory K. Maxey
Dim oPar As Paragraph, oWord As Range
  Set oPar = ActiveDocument.Range.Paragraphs(5)
    For Each oWord In oPar.Range.Words
      oWord.Select
    Next
lbl_Exit:
  Exit Sub
End Sub

[RobiNew]

Thank you, Gmaxey! That was a typo, I meant Words(1). That code was part of the larger set here below. It works, but perhaps it can be made more efficient? Thanks a lot!

Sub ChrSixBis()
  With ActiveDocument
If .Paragraphs(5).Range.Words(1) = "title" And .Paragraphs(5).Range.Characters(6) = "." _
Or .Paragraphs(5).Range.Words(1) = "Title" And .Paragraphs(5).Range.Characters(6) = "." _
Or .Paragraphs(5).Range.Words(1) = "TITLE" And .Paragraphs(5).Range.Characters(6) = "." Then
    .Paragraphs(5).Range.Style = "myStyle"
    .Paragraphs(5).Range.Words(1).Case = wdLowerCase
    .Paragraphs(5).Range.Words(1).Font.SmallCaps = True
Else
MsgBox "Not Found"
End If
End With
End Sub

[Guessed]

This might be easier

Sub ChrSixBis()
  With ActiveDocument.Paragraphs(5).Range
    If LCase(.Text) Like "title.*" Then
      .Style = "Heading 1"
      .Words(1).Case = wdLowerCase
      .Words(1).Font.SmallCaps = True
    Else
      MsgBox "Not Found"
    End If
  End With
End Sub

I would recommend you add an error checker in case the document doesn't have 5 paragraphs. Also, if you are trying to assign a custom style, you might also need an error checker to ensure that style exists in the document.

[RobiNew]

Thank you very much indeed, Guessed! Could you please explain the magics of '*' ?

[Guessed]

The * is 'something else'. That test is basically saying does the paragraph start with the string "title." and then followed by anything else.

[RobiNew]

I see. Thanks a lot!