Sub bhh_inlineBookmarks()
  ' Written by Brian Hoard, www.BrianHoard.com

  Dim scriptName As String
  scriptName = "bhh_inlineBookmarks"
  
  Application.ScreenUpdating = False
    
  ' Begin undo record
  Dim bhhUndo As UndoRecord
  Set bhhUndo = Application.UndoRecord
  bhhUndo.StartCustomRecord (scriptName)

  Dim f As Field
  Dim rngSource As Range
  Dim rng_bm As Range
  Dim i As Integer
  
  i = 1 ' Begin hyperlink counter
  For Each f In ActiveDocument.Fields
    If f.Type = wdFieldHyperlink Then
      f.Select
      Set rngSource = Selection.Range
      f.Delete ' Delete the link
      
      ' Define the range in the document body where the bookmark is at.
      With rngSource
        .Collapse
        .Font.Superscript = False
      End With
      
      ' Process the linked text.
      ' NOTE: This is subject to problems if the document includes hyperlinks that are not bookmarks.
      Set rng_bm = ActiveDocument.Bookmarks.Item(i).Range

      With rng_bm
        .Expand wdParagraph ' Expand the range to the full paragraph
        .End = .End - 1 ' Bring range End to the left 1 character to exclude the carriage return.
      End With

      rngSource.Text = (" [" & rng_bm.Text & "]")

    End If ' /f.Type = wdFieldHyperlink

    i = (i + 1) ' increment bookmark counter

  Next f

  ' End undo
  bhhUndo.EndCustomRecord
  
  Application.ScreenUpdating = True

End Sub

Sub MoveHyperlinkedText()
    Dim hlIdx As Long, hlink As Hyperlink, hlRng As Range
    Dim bmName As String, bmRng As Range
    
    If ActiveDocument.Hyperlinks.Count > 0 And ActiveDocument.Bookmarks.Count > 0 Then
        Application.ScreenUpdating = False
        'because hyperlinks will be deleted it is necessary to process them in reverse order
        For hlIdx = ActiveDocument.Hyperlinks.Count To 1 Step -1
            Set hlink = ActiveDocument.Hyperlinks(hlIdx)
            If hlink.Type = msoHyperlinkRange Then  'ignore any hyperlinked shapes
                If hlink.Address = vbNullString Then
                    'it's a link to a location in the same document so ensure that it exists
                    bmName = hlink.SubAddress
                    If ActiveDocument.Bookmarks.Exists(bmName) Then
                        'get range of bookmarked paragraph, minus the paragraph mark
                        Set bmRng = ActiveDocument.Bookmarks(bmName).Range
                        With bmRng
                            .Expand wdParagraph
                            .End = .End - 1
                        End With
                        Set hlRng = hlink.Range
                        hlink.Delete
                        With hlRng
                            'turn off superscript and replace text with brackets
                            .Font.Superscript = False
                            .Text = " []"
                            .Start = .Start + 2
                            .End = .End - 1
                            'add the bookmarked text and its formatting
                            .FormattedText = bmRng.FormattedText
                        End With
                    End If
                End If
            End If
        Next hlIdx
        Application.ScreenUpdating = True
    End If

End Sub