Add text at beginning of cells in Word table

[WJSwanepoel]

How can I add a text string at the beginning of each of the lefthand cells in a table?



Lets say the cell contains "1:2" I wish to add "Gen. " so that it reads "Gen. 1:2"

The start of every lefthand cell must be set to "Gen. "

[gmaxey]

Sub ScratchMacro()
'A basic Word macro coded by Greg Maxey
Dim oTbl As Table
Dim oCell As Cell
  Set oTbl = Selection.Tables(1)
  For Each oCell In oTbl.Range.Cells
    If oCell.ColumnIndex = 1 Then
      If Len(oCell.Range.Text) > 2 Then
        oCell.Range.InsertBefore "Gen "
      End If
    End If
  Next
lbl_Exit:
  Exit Sub
End Sub
Sub ScratchMacro2()
'A basic Word macro coded by Greg Maxey
Dim oTbl As Table
Dim oCol As Column
Dim oCell As Cell
  Set oTbl = Selection.Tables(1)
  If oTbl.Uniform Then
    Set oCol = oTbl.Columns(1)
    For Each oCell In oCol.Cells
      If oCell.ColumnIndex = 1 Then
        If Len(oCell.Range.Text) > 2 Then
          oCell.Range.InsertBefore "Gen "
        End If
      End If
    Next
  End If
lbl_Exit:
  Exit Sub
End Sub

If the table is uniform, the second macro will be faster.

[WJSwanepoel]

Thank you!