How can I delete a blank line with Word VBA if it is followed by another blank line?

[jamu]

How can I delete a blank line with Word VBA if it is followed by another blank line? So replace two empty lines with one empty line?

[gmayor]

The following should work - see Replace using wildcards

Sub Macro1()
Dim oRng As Range
    Set oRng = ActiveDocument.Range
    With oRng.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Text = "(^13){2,}"
        .Replacement.Text = "\1"
        .MatchWildcards = True
        .Execute Replace:=wdReplaceAll, Wrap:=wdFindStop
    End With
    Set oRng = Nothing
End Sub

[jamu]

Thanks, unfortunately it does not work, or only if I use {2} instead of {2,}. However, it then unfortunately also deletes the blank line in cases like this (P for paragraph):
"blablablaP
P
blablabla"
becomes


"blablabla
blablalba"

Moreover, it does not delete the line here between two lines:

last table row table 1
empty line
empty line
first table row table 2

[gmayor]

Can you post a sample document?

[macropod]

Find/Replace can't be used to delete an empty paragraph before a table - even with a macro. For any other case, you don't even need a macro - simply use a wildcard Find/Replace, where:
Find = ^13{2,}
Replace = ^p
This is essentially what Graham's macro does.

[jamu]

Thank you very much for your help. Here is a sample document. Some tables in the document ever after are gone and I have a macro to remove blank row, but for example when a whole table is dropped there are no rows from that table but there are at least two blank rows (the blank row before and after the table).




Searching and replacing with macropod's search text somehow doesn't work for me, maybe it's the language settings, I'm going to try it with English.

[macropod]

You're evidently using a system with non-English regional settings. You could change the wildcard Find/Replace to:
Find = ^13{2;}
Replace = ^p

[jamu]

Thanks, it unfortunately did not replace the two empty lines between two tables with an empty line.Did the replacement work for you with this document?

[macropod]

As I said in post #5:

Originally Posted by macropod

Find/Replace can't be used to delete an empty paragraph before a table - even with a macro.

A macro you could use is:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "[^13]{2,}"
    .Replacement.Text = "^p"
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchWildcards = True
    .Execute Replace:=wdReplaceAll
    .Wrap = wdFindStop
  End With
  Do While .Find.Execute
    .End = .End - 1
    .Text = vbNullString
    .Collapse wdCollapseEnd
  Loop
End With
Application.ScreenUpdating = True
End Sub

The 'wdReplaceAll' reduces all consecutive paragraph breaks other than before a table to single paragraph breaks; the loop handles consecutive paragraph breaks before tables.

[jamu]

Thanks for your help, the problem has been solved.