Trying to get the shortest line of code for copying from one cell to the next

[gbrew584]

Hi, all and thanks for reading my question. I am not very good with vba but I am trying to learn. while I was practicing, I was wondering how short I could make a line of code.





So I made a word document that consist of 1 table. The table is 5 columns with 2 rows. In the fist cell on the first row I have the text "is this working".


I am trying to copy the text from the first cell on row 1 to the first cell on row 2.


I ran the code below. It captures the desired text but it doesn't leave (or insert, input) the text in the cell on row 2. (sorry if I am not using the correct terminology)



I think maybe the T1 and T2 variables are wrong but I am not sure what they should be other than String.


If someone could please let me know what I am missing I would appreciate it.



Sub CopyPaste1() ' copy information from 1 cell


Dim AD As Document
Dim TB As Tables
Dim ST As Integer
Dim C1 As Cell
Dim C2 As Cell
Dim RG1 As Range
Dim RG2 As Range
Dim T1 As String
Dim T2 As String

Set AD = ActiveDocument
Set TB = AD.Tables
ST = 1
Set C1 = TB(ST).Cell(1, 1)
Set C2 = TB(ST).Cell(2, 1)
Set RG1 = C1.Range
Set RG2 = C2.Range
T1 = RG1.Text
T2 = RG2.Text

T2 = Left(T1, Len(T1) - TB(ST).Rows.Count)

End Sub

[gbrew584]

I should probably use trim instead of Len, too . It looks like trim will not work to remove the end of cell mark, i guess I'll have to stick with using Len for now.

[macropod]

As a single line of code:

With ActiveDocument.Tables(1): .Cell(2, 1).Range.Text = Split(.Cell(1, 1).Range.Text, vbCr)(0): End With

[gbrew584]

Thanks very much for the reply, but that is not the result I was looking for (however, I do like the vbCr usage. I will have to look into that one a little deeper).


I am trying to end up with a line of code that would look something like this:
T2 = Left(T1, Len(T1) - 2)


Keeping all the Dim and Set statements I have. Its kinda an odd way to do it, but I'm just experimenting. Thanks for your help.

[macropod]

The conventional way of doing things would be something along the lines of:

Sub Demo()
Dim Rng As Range
With ActiveDocument.Tables(1)
  Set Rng = .Cell(1, 1).Range
  Rng.End = Rng.End - 1
  .Cell(2, 1).Range.Text = Rng.Text
End With
End Sub

What you need to understand is that the end-of-cell marker (i.e. ¤) consists of two characters but, like a paragraph break, occupies only one character space. Hence, moving the Range end backwards by one character is sufficient to eliminate the end-of-cell marker but, if you're using Len() and the like, you need to deduct two characters for the end-of-cell marker (e.g. Left(.Cell(1, 1).Range.Text, Len(.Cell(1, 1).Range.Text) - 2)).

[gbrew584]

Thanks for the information and thanks for the suggestions I will give them a try.