Keeping a macro from going beyond selection

[Ulodesk]

A session with the boss today stipulated certain optional space-saving formatting, which I am trying to put into a macro. The attached sample doc illustrates an original format and intended result.



Here's my recorded macro, which applies itself to the end of the document rather than stopping with the selection, highlighted here for clarity.

The lack of close parenthesis after the date format is simply something I don't know how to specify.

Sub BulletsToPara()
'
' BulletsToPara Macro
'
'
    Selection.Style = ActiveDocument.Styles("N-BodyText,n-bd")
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = "^t"
        .Replacement.Text = " ("
        .Forward = True
        .Wrap = wdFindAsk
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
    With Selection.Find
        .Text = "^13"
        .Replacement.Text = ". "
        .Forward = True
        .Wrap = wdFindAsk
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = "(..)"
        .Replacement.Text = "."
        .Forward = True
        .Wrap = wdFindAsk
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = ". . "
        .Replacement.Text = ". "
        .Forward = True
        .Wrap = wdFindAsk
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
    Selection.MoveLeft Unit:=wdCharacter, Count:=1
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = ".."
        .Replacement.Text = "."
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
End Sub

[Guessed]

Try this version

Sub BulletsToPara()
  Selection.Style = ActiveDocument.Styles("N-BodyText,n-bd")
  With Selection.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "^t(*)^13"
    .Replacement.Text = " (\1)^13"
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = True
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute Replace:=wdReplaceAll

    .Text = "^13"
    .Replacement.Text = ". "
    .MatchWildcards = False
    .Execute Replace:=wdReplaceAll
    
    .Text = "(..)"    'not seeing the use of this one???
    .Replacement.Text = "."
    .Execute Replace:=wdReplaceAll
    
    .Text = ". . "
    .Replacement.Text = ". "
    .Execute Replace:=wdReplaceAll
  End With
End Sub

[Ulodesk]

Thank you very much , Andrew. I'm trying to learn from each one, and I think I understand a ew things better, since, for example, yours does not produced the several "do you want to continue" dialogues that mine does.

You left a note asking about the relevancy of replacing double periods with a single. For some reason, your macro leaves a double period anyway -- just one, right after "requirement". It's because, unlike the others, there is a period in the original, as would be the case if this were a completed resume and the paragraph between the Position, Employer line and first bullet were one or more complete sentences.

Would adding {1,} to the text-to-be-replaced period solve this, or maybe it's a matter of the order in which the actions are carried out?

Please forgive me for requesting one additional action, if I may. I have spent a half-hour trying to figure out how to add a removal of italics from any text in the selection to the macro, since I had forgotten that this is sometimes also needed (I did not include any in my sample). I tried recording, using a find-replace action, but once in the macro, either it returned some coding error message or simply did not remove the italics.

[Guessed]

My question was about looking for (..) which was double periods inside brackets. I didn't see why that one was necessary. If you have double periods not inside brackets then you can add that case at the bottom.

You can remove italics right up the top by adding this line below the one included

Selection.Style = ActiveDocument.Styles("N-BodyText,n-bd")
Selection.Font.Italic = False

Alternatively, you can remove all local font attributes (bold, italic, colour, size etc) which might be overriding the style's font settings by using this line instead

Selection.Font.Reset

[Ulodesk]

Bravo again, Andrew. It's perfect now. Mille gracie. (That is Australian, isn't it?)