Insert a picture from userform into bookmark in word document

[dyb]

I am a novice at vba but have created a userform to be used to insert customer data into bookmarks in a word template. All of the code inserting text from text boxes on the userform works fine but it doesn't work for the image. Instead of the image it uploads a string of numbers. The relevant part of the code is below:



Dim Proposal As Range
Set Proposal = ActiveDocument.Bookmarks("Proposal").Range
Proposal = Me.Image1.Picture

The bookmark name is Proposal which is where I want a JPG image (Image1) to be placed. The image has been uploaded to the userform via a command button and is visible on the userform.

Any help to correct the code would be much appreciated.

[gmayor]

You need to save the image from the userform as a temporary file then insert that temporary file at the bookmark.

Call the image using the following sub as follows:

UserformImageToBM "Proposal", Image1.Picture

Private Sub UserFormImageToBM(strbmName As String, oImage As Object)
'Graham Mayor - http://www.gmayor.com
'UserformImageToBM "bookmarkName", Image1.Picture
Dim oRng As Range
Dim TempFile As String
Dim FSO As Object
    Set FSO = CreateObject("Scripting.FileSystemObject")
    TempFile = Replace(FSO.GetTempName, "tmp", "bmp")
    SavePicture oImage, TempFile
    With ActiveDocument
        On Error GoTo lbl_Exit
        Set oRng = .Bookmarks(strbmName).Range
        oRng.Text = ""
        oRng.InlineShapes.AddPicture _
                FileName:=TempFile, LinkToFile:=False, _
                SaveWithDocument:=True
        oRng.End = oRng.End + 1
        oRng.Bookmarks.Add strbmName
    End With
    Kill TempFile
lbl_Exit:
    Set FSO = Nothing
    Set oRng = Nothing
    Exit Sub
End Sub

[dyb]

That worked brilliantly Graham, thanks so much.

[dyb]

Hi Graham

Is it possible specify the height of the image and also lock the aspect ratio within that code?

[gmayor]

You can apply any of the available formatting parameters to the image - here the height is set to 0.5":

Private Sub UserFormImageToBM(strbmName As String, oImage As Object)
'Graham Mayor - https://www.gmayor.com
'UserformImageToBM "bookmarkName", Image1.Picture
Dim oRng As Range
Dim TempFile As String
Dim oShape As InlineShape
Dim FSO As Object
    Set FSO = CreateObject("Scripting.FileSystemObject")
    TempFile = Replace(FSO.GetTempName, "tmp", "bmp")
    SavePicture oImage, TempFile
    With ActiveDocument
        On Error GoTo lbl_Exit
        Set oRng = .Bookmarks(strbmName).Range
        oRng.Text = ""
        Set oShape = oRng.InlineShapes.AddPicture _
                     (Filename:=TempFile, LinkToFile:=False, _
                      SaveWithDocument:=True)
        With oShape
            .LockAspectRatio = msoTrue
            .Height = InchesToPoints(0.5)
        End With
        oRng.End = oRng.End + 1
        oRng.Bookmarks.Add strbmName
    End With
    Kill TempFile
lbl_Exit:
    Set FSO = Nothing
    Set oRng = Nothing
    Exit Sub
End Sub

[dyb]

Thanks Graham, that worked great.