Delete First and Last Rows If....

[JingleBelle]

With help from the experts at this forum, I crafted the following macro to search for a specific text string. If the text is found within a table, the row is deleted.



Would you help me further restrict this code to only look in the first row and the last row of all tables? I am certainly okay with running two macros if that is less complicated.

Thank you in advance for considering my request for help.

Sub DeleteRowIf()

Application.ScreenUpdating = False

  Dim MyRange As Range
  Set MyRange = ActiveDocument.Range
  With MyRange.Find
    .ClearFormatting
    .Text = "TEXT TO FIND"
    .MatchCase = True
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    While .Execute
      If MyRange.Information(wdWithInTable) Then
          MyRange.Rows(1).Delete
      End If
    Wend
  End With

Application.ScreenUpdating = True
Application.ScreenRefresh
MsgBox "Done!", vbInformation

End Sub

[Guessed]

This shows you the extra test to work out if it is a first or last row.

Sub DeleteRowIf()
  Dim MyRange As Range
  Set MyRange = ActiveDocument.Range
  With MyRange.Find
    .ClearFormatting
    .Text = "TEXT TO FIND"
    .MatchCase = True
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    While .Execute
      If MyRange.Information(wdWithInTable) Then
        If MyRange.Rows.First.Range = MyRange.Tables(1).Rows.First.Range Or MyRange.Rows.First.Range = MyRange.Tables(1).Rows.Last.Range Then
          MyRange.Rows(1).Delete
        End If
      End If
    Wend
  End With
  MsgBox "Done!", vbInformation
End Sub

The issue is if your search term is in both first and second rows. After the first row is deleted, the second row becomes the NEW first row so it will also be deleted. If that is going to be a problem, you can move the range so it searches down from the subsequent row.

[JingleBelle]

Hey, Andrew.


Thank you for adjusting the code for me. There is NO way I would have come up with that on my own.


It works like charm, and I appreciate the tip about the search term being in the first and second row. Of course, that had not occurred to me. I don't think that will be an issue.


The macro works as I wanted; however, it did fail when it encountered a table with a vertically merged cell. I had not considered that obstacle either. I think, though, in my notes somewhere or in some code I picked up on this forum, there is a way to avoid or skip over those tables. With any luck, I will be able to cobble the two together and get it to work. Having said that, I may be back.


Thank you, again, for your willingness to help me. I appreciate it very much.