find replace to all open documents

yacov · #1 10-05-2021, 11:18 PM

Hi.
I am looking for a macro to find and replace text between all open documents.

I found a lot of macros on the internet, but they all open the files and after the replacement close them. And I want the files to stay open after the replacment.

Is it possible to change such a macro so that instead of selecting a folder it will perform the operation on the files that are already open?

thanks.
Yacov

Guessed · #2 10-06-2021, 04:00 AM

Looping through currently open documents is easy

Code:

Sub DocsOpen()
  Dim aDoc As Document
  For Each aDoc In Application.Documents
    MsgBox aDoc.Name
  Next aDoc
End Sub

yacov · #3 10-06-2021, 06:59 AM

Thanks a lot.
I did not quite understand the logic, when to run the macro because sometimes it works and sometimes it does not work for me.
should I perform a search / replace in one file anf only after that need to run the macro?

yacov · #4 10-06-2021, 09:52 AM

I tried my luck, and I have no luck :-)
Help would be appreciated

Sub MFindReplace()
Dim aDoc As Document
Dim strFindText As String
Dim strReplaceText As String
With Selection
.HomeKey Unit:=wdStory
With Selection.Find
.Text = strFindText
.Replacement.Text = strReplaceText
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
For Each aDoc In Application.Documents
MsgBox aDoc.Name
Next aDoc
End With
End Sub

Guessed · #5 10-06-2021, 07:49 PM

Like this

Code:

Sub MFindReplace()
  Dim aDoc As Document, strFindText As String, strReplaceText As String
  strFindText = "Finders"
  strReplaceText = "Keepers"
  For Each aDoc In Application.Documents
    With aDoc.Range.Find
      .Text = strFindText
      .Replacement.Text = strReplaceText
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute Replace:=wdReplaceAll
    End With
  Next aDoc
End Sub

yacov · #6 10-06-2021, 11:01 PM

Thanks a lot Guessed. works great

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Find or replace in all word documents	jkathir	Word	6	08-30-2019 07:27 AM
Find & Replace text in Field Code across multiple documents	RPM7	Word VBA	6	05-12-2017 12:58 AM
Find & replace footer text in a folder of Word 2010 documents	kennethc	Word	3	03-28-2015 02:49 AM
How do I find/replace the same word in multiple documents?	Ineedhelp!	Word	3	03-04-2014 03:50 PM
Find and replace multiple documents change style	BaPW	Word	0	08-14-2011 11:12 AM