Finding the position of a keyword in a seamless way

alex100 · #1 10-26-2020, 09:56 AM

I am using the routine below to find the position of a keyword inside a document.

The problem is that the code will also select the matching text, and reposition the page so that this will be displayed at the top of the Word application.

How can I get the position of the keyword in a seamless way, without having it selected and the page repositioned, please?

Code:

With Selection.Find
    .ClearFormatting
    .Text = "keyword"
    .Font.Size = 10
    .Font.Name = Verdana
    .Forward = True
    .Wrap = wdFindStop
    .Execute
    If .Found = True Then
        Position = Selection.Start
    End If
End With
MsgBox (Position)

Alex

Guessed · #2 10-26-2020, 03:05 PM

If you don't want to change the selection, you use Ranges instead

Code:

Sub aTest()
  Dim aRng As Range
  Set aRng = ActiveDocument.Range
  With aRng.Find
    .ClearFormatting
    .Text = "keyword"
    .Font.Size = 10
    .Font.Name = "Verdana"
    .Forward = True
    .Wrap = wdFindStop
    .Execute
    If .Found = True Then
      MsgBox "Found at: " & aRng.Start
    Else
      MsgBox "Not found"
    End If
  End With
End Sub

alex100 · #3 10-27-2020, 01:03 AM

Works great, thank you very much!

Alex

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Finding raised characters by 0.5 pt step (Font.Position pb)	iwonder	Word VBA	1	07-14-2017 07:57 AM
Only display rows containing a keyword?	King Mustard	Excel	2	04-07-2017 12:06 AM
Textboxes position isn't equal to initial position	dxdevil	Word VBA	0	01-30-2017 04:32 AM
Finding the graphics and inserting the keyword	Ajay2506	Word VBA	4	06-28-2016 05:34 AM
Multiple keyword search in WORD	tvincent8118	Word VBA	1	06-23-2015 04:45 AM