Using VBA to find html img code, and insert images dynamically

[noslenwerd]

I am repurposing code that macropod had authored in a previous post for finding html for links, and converting the hyperlinks with custom text in a word document.

For reference that code is below:

Sub ConvertHyperlinks()
Dim StrAddr As String, StrDisp As String
' Turn Off Screen Updating
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .Text = "\<[Aa] href=([!\>]@)\>([!\<]@)\</a\>"
    .ClearFormatting
    .Replacement.ClearFormatting
    .Replacement.Text = ""
    .Forward = True
    .MatchWildcards = True
    .Wrap = wdFindStop
    .Execute
  End With
  Do While .Find.Found = True
    StrAddr = Replace(Replace(Replace(Split(Split(.Text, ">")(0), "=")(1), Chr(34), ""), Chr(147), ""), Chr(148), "")
    StrDisp = Split(Split(.Text, ">")(1), "<")(0)
    .Hyperlinks.Add Anchor:=.Duplicate, _
      Address:=StrAddr, TextToDisplay:=StrDisp
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
' Restore Screen Updating
Application.ScreenUpdating = True
End Sub

I am trying to repurpose that code to do the same for html code for images.

Essentially I want the macro to find all instances of <img src="c:\users\8172837\worksheet\test.jpg">, and embed that image into the document.

Below is the code I came up with, but I am running into issues. Admittedly I am not understanding the wildcards that macropod used here, but I tried researching to the best of my abilities.

Sub ConvertImages()
Dim StrAddr As String
' Turn Off Screen Updating
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .Text = "\<img src=([!\>]@)\>"
    .ClearFormatting
    .Replacement.ClearFormatting
    .Replacement.Text = ""
    .Forward = True
    .MatchWildcards = True
    .Wrap = wdFindStop
    .Execute
  End With
  Do While .Find.Found = True
    StrAddr = Replace(Replace(Replace(Split(Split(.Text, ">")(0), "=")(1), Chr(34), ""), Chr(147), ""), Chr(148), "")
	InlineShapes.AddPicture FileName:=StrAddr, LinkToFile:=False
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
' Restore Screen Updating
Application.ScreenUpdating = True
End Sub

[macropod]

Try:

Sub ConvertImageLinks()
Dim StrImg As String
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .Text = "\<img src=[!\>]@\>"
    .ClearFormatting
    .Replacement.ClearFormatting
    .Replacement.Text = ""
    .Forward = True
    .MatchWildcards = True
    .Wrap = wdFindStop
    .Execute
  End With
  Do While .Find.Found = True
    StrImg = Replace(Replace(Replace(Split(Split(.Text, ">")(0), "=")(1), Chr(34), ""), Chr(147), ""), Chr(148), "")
    .Text = vbNullString
    .InlineShapes.AddPicture StrImg, False, True, .Duplicate
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
End Sub

[noslenwerd]

Works perfectly!

Is there anyway to parlay alignment and text wrap into this? I tried the code below, but the bolded code does not work.

Sub DSSImages()
Dim StrImg As String
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .Text = "\<img src=[!\>]@\>"
    .ClearFormatting
    .Replacement.ClearFormatting
    .Replacement.Text = ""
    .Forward = True
    .MatchWildcards = True
    .Wrap = wdFindStop
    .Execute
  End With
  Do While .Find.Found = True
    StrImg = Replace(Replace(Replace(Split(Split(.Text, ">")(0), "=")(1), Chr(34), ""), Chr(147), ""), Chr(148), "")
    .Text = vbNullString
    .InlineShapes.AddPicture StrImg, False, True, .Duplicate
    .WrapFormat.Type = wdWrapSquare
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
End Sub

Lastly... (I am not asking you to write this code, I am curious if anything exits):

We need to source all of our images. So I would love to find a way to have the html below, pull in the image, and have a source link below it (where we found the image in the first place).

<img src="C:\test\logo.jpg" cap="http://linktothesource.com">

[macropod]

Originally Posted by noslenwerd

Is there anyway to parlay alignment and text wrap into this?

Change:
.InlineShapes.AddPicture StrImg, False, True, .Duplicate
to:
ActiveDocument.Shapes.AddPicture StrImg, False, True, , , , , .Duplicate

Note that the empty arguments allow you to define the size & position - see the VBA help file for more details.

Originally Posted by noslenwerd

We need to source all of our images. So I would love to find a way to have the html below, pull in the image, and have a source link below it (where we found the image in the first place).

<img src="C:\test\logo.jpg" cap="http://linktothesource.com">

Delete:
.Text = vbNullString