Preserving formatting when turning footnotes into regular text

thiagoafdoria · #1 12-26-2019, 11:04 PM

Hi!

I'm using the following macro to turn footnotes into delimited fragments between "[!" and "!]" in the body of the text:

Code:

Sub demo()
Application.ScreenUpdating = False
With ActiveDocument
  Do While .Footnotes.Count > 0
    With .Footnotes(1)
      .Reference.InsertAfter "[!" & .Range.FormattedText & "!]"
      .Delete
    End With
  Loop
End With
Application.ScreenUpdating = True
End Sub

Just now I've realized that the formatting, i.e. bold and italics, are not preserved after I run the macro. So if I have, say, "table" in the footnote, that will turn into "table" in the body of the text.
Is that something I could do to make the macro preserve the formatting?
Thank's!

Thiago

macropod · #2 01-01-2020, 04:09 AM

Try:

Code:

Sub Demo()
Application.ScreenUpdating = False
Dim Rng As Range
With ActiveDocument
  Do While .Footnotes.Count > 0
    With .Footnotes(1)
      Set Rng = .Reference
      With Rng
        .Collapse wdCollapseStart
        .Text = "[!!]"
        .Start = .Start + 2
        .Collapse wdCollapseStart
      End With
      Rng.FormattedText = .Range.FormattedText
      .Delete
    End With
  Loop
End With
Application.ScreenUpdating = True
End Sub

thiagoafdoria · #3 01-08-2020, 01:25 PM

Excellent! Thank you!

Thread Tools
Show Printable Version Email this Page
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Changing words with bold and italics and turning "regular" words into italicized and bold ones	thiagoafdoria	Word VBA	4	12-02-2019 11:41 AM
regular expressions in footnotes	loes	Word	3	09-04-2019 07:52 AM
Word Problems - text turning to gibberish	Dw1	Word	4	06-17-2015 01:07 PM
Regular expressions for text with complex formatting	Kreol2013	Word VBA	1	04-12-2013 07:33 PM
regular Expressions Formatting for Search	sesproul	Mail Merge	1	11-30-2011 05:02 AM