Inserting Icons into TextBox

LSMcD · #1 11-04-2019, 02:20 PM

Hi - first post, so apologies for any errors...

I am building a set a macros that can be used to quickly insert a textbox with a pre-determined icon inside it. I have been able to successfully build the textbox and select it, but I don’t know how to get the cursor inside the box to add the icon graphic so that it resides within the textbox.

The following routine adds a textbox to the document in the place and size I want it, and selects the textbox border. I want to get the cursor inside the textbox so that I can then add the icon.

With just the TextBox selected (cursor not inside the box) I am getting “Method 'AddPicture' of object 'InlineShapes' failed" when I try to add the icon. Here’s what I have:

--------------------------------------------------------
Sub SetWindowUp()
Dim winMain As Window
Dim Box As Shape

For Each winMain In Windows
winMain.View.Zoom.Percentage = 100
Next winMain
Application.ActiveWindow.View.Type = WdViewType.wdPrintView

x = Selection.Information(wdHorizontalPositionRelative ToPage)
y = Selection.Information(wdVerticalPositionRelativeTo Page)

Set Box = ActiveDocument.Shapes.AddTextbox( _
Orientation:=msoTextOrientationHorizontal, _
Left:=x, Top:=y, Width:=50, Height:=50)

boxName = Box.Name

ActiveDocument.Shapes.Range(boxName).Select

' the following line gives me error: "Method 'AddPicture' of object 'InlineShapes' failed":

Selection.InlineShapes.AddPicture FileName:= _
"https://cdn.hubblecontent.osi.office.net/firstpartycontent/internal/icons/wheelchairaccess.svg" _
, LinkToFile:=False, SaveWithDocument:=True
End Sub
----------------------------------------------------
Sub Macro2()

' This is a macro I recorded that started with where I clicked
' on the selected textbox (left over by the previous routine above) and placed the cursor inside the box.
' From there I could insert the icon using this line - but here the TextBox name is literal, not a variable.
'
ActiveDocument.Shapes.Range(Array("Text Box 37")).Select
Selection.InlineShapes.AddPicture FileName:= _
"https://cdn.hubblecontent.osi.office.net/firstpartycontent/internal/icons/wheelchairaccess.svg" _
, LinkToFile:=False, SaveWithDocument:=True

End Sub

------------------------------------
What do I need to be doing to be able to insert the icon into the newly created textbox?
Am new to VBA so any assistance most appreciated!

gmayor · #2 11-04-2019, 10:01 PM

Insert a shape rather than a text box

Code:

Sub SetWindowUp()

Dim winMain As Window
Dim Box As Shape
Dim x As Double, y As Double
Dim sPath As String
    sPath = Environ("USERPROFILE") & Chr(92) & "Pictures\"
    For Each winMain In Windows
        winMain.View.Zoom.Percentage = 100
    Next winMain
    Application.ActiveWindow.View.Type = WdViewType.wdPrintView

    x = Selection.Information(wdHorizontalPositionRelativeToPage)
    y = Selection.Information(wdVerticalPositionRelativeToPage)

    Set Box = ActiveDocument.Shapes.AddPicture _
              (FileName:=sPath & "\wheelchair access.png", _
               LinkToFile:=False, _
               SaveWithDocument:=True, _
               Left:=x, Top:=y, Width:=50, Height:=50)
End Sub

The file path in your original effort does not contain an insertable graphic, however the attached is an insertable version of that image, which you should save in your Pictures folder for it to work with the code above.

Personally I would probably just insert an inline shape at the cursor

Code:

Sub InsertIcon()
Dim winMain As Window
Dim Box As InlineShape
Dim x As Double, y As Double
Dim sPath As String
    sPath = Environ("USERPROFILE") & Chr(92) & "Pictures\"
    Application.ActiveWindow.View.Type = WdViewType.wdPrintView

    Set Box = Selection.Range.InlineShapes.AddPicture _
              (FileName:=sPath & "\wheelchair access.png", _
               LinkToFile:=False, _
               SaveWithDocument:=True)
    With Box
        .Width = 50
        .Height = 50
    End With
End Sub

LSMcD · #3 11-05-2019, 09:05 AM

Wow, thanks for the help and your ideas. Appreciate your time and help gmayor!

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
syntax for inserting blank line before inserting table and after a line or paragraph	SamDsouza	Word VBA	8	08-04-2019 11:10 PM
Display result in textbox based on the input of another textbox	scarymovie	Word VBA	5	05-16-2012 07:05 PM
What Do The Different Calendar Icons Mean?	mysticglow3	Outlook	1	05-14-2012 09:42 PM
2 printer icons	Topazdan	Office	3	05-18-2010 01:35 AM
Icons for different folders	pengyou	Windows	3	12-09-2009 09:21 AM