Help creating VBA code to search multiple word documents for specific group of words

[dmreno]

I have no VBA coding experience and I am looking for help to create a Macro which will search through 200 word documents to determine if any of a group of individual words ( storage, dry, spent, ISFSI or fuel). I also need to have a summary document created which will show the document name and which words were in the document.

Also, Could this macro search for same in a .pdf file or convert the pdf to word and then search?

Thanks to anyone who could help.

[macropod]

For Word documents, try:

Sub CollateDocumentData()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, strDocNm As String, strTmp As String, strOut As String
Dim wdDoc As Document, i As Long: Const StrFnd As String = "storage,dry,spent,ISFSI,fuel"
strDocNm = ActiveDocument.FullName
strFolder = GetFolder: If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""
  If strFolder & "\" & strFile <> strDocNm Then
    Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
    strTmp = ""
    With wdDoc
      With .Range.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .MatchCase = False
        .MatchWholeWord = True
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
        For i = 0 To UBound(Split(StrFnd, ","))
          .Text = Split(StrFnd, ",")(i)
          .Execute
          If .Found = True Then strTmp = strTmp & ", " & Split(StrFnd, ",")(i)
        Next
      End With
      If strTmp <> "" Then strOut = strOut & vbCr & strFile & ": " & strTmp
      .Close SaveChanges:=True
    End With
  End If
  strFile = Dir()
Wend
Set wdDoc = Nothing
ActiveDocument.Range.Text = "The following matches were made:" & strOut
Application.ScreenUpdating = True
End Sub

Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function

To do the same for pdfs, you could change:
strFile = Dir(strFolder & "\*.doc", vbNormal)
to:
strFile = Dir(strFolder & "\*.pdf", vbNormal)

For PC macro installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm

[srikanthg2310]

how do i run the same vba in excel ? also, how do i loop through sub-folders within a folder? thanks.

[macropod]

Originally Posted by srikanthg2310

how do i run the same vba in excel ?

You don't - the code would have to be completely re-written to be run from Excel.

Originally Posted by srikanthg2310

also, how do i loop through sub-folders within a folder? thanks.

For an idea of the modifications needed to make the above code do that, see: https://www.msofficeforums.com/47347-post12.html