Toggle between pagecolumns / pagefit view

[eduzs]

Hello!


I have this code that is toggle between pagecolumns / pagefit view.
But it is not working properly.
It only works the first time it runs.
Any sugestions? Thanks.

Sub View_Zoom_Alternate()

If ActiveWindow.ActivePane.View.Zoom.PageFit = wdPageFitBestFit Then
    With ActiveWindow.ActivePane.View.Zoom
        .PageColumns = 5
        .PageRows = 2
    End With
Else
    ActiveWindow.ActivePane.View.Zoom.PageFit = wdPageFitBestFit
End If

End Sub

[Guessed]

wdPageFitBestFit has a value of 2 but when you set the line
ActiveWindow.ActivePane.View.Zoom.PageFit = wdPageFitBestFit
word looks at the window size and sets the page zoom to best fit that window. Which means the return value of .PageFit is going to be a specific zoom number rather than 2. The more useful setting to hang your test on would be the .pagecolumns since bestfit is changing that to 1 and this would be consistent regardless of the window or paper size.

Try...
If ActiveWindow.ActivePane.View.Zoom.PageColumns = 1 Then

[eduzs]

Thanks.
That's also not working, even this still not works:

If ActiveWindow.ActivePane.View.Zoom.PageFit = 1 Or ActiveWindow.ActivePane.View.Zoom.PageFit = 2 Or ActiveWindow.ActivePane.View.Zoom.PageColumns = 1 Then..

[Guessed]

So do some testing.

Start the macro by pressing F8 and hover over some of the values to see what values it is returning. eg.
ActiveWindow.ActivePane.View.Zoom.PageColumns
ActiveWindow.ActivePane.View.Zoom.PageFit

Once you understand what values are being returned, you can choose the correct If test

[eduzs]

I suspect the problem is not the IF statement, but this part has no effect after 1st run:

With ActiveWindow.ActivePane.View.Zoom
.PageColumns = 5
.PageRows = 2
End With

[eduzs]

Solved! The problem was that the page columns / rows are not reset when the pagefit/bestfit adjustment is set.
So It is necessary to set it back again to 1 when toggling to PageFitBestFIt

Sub Toggle_View_Zoom()

If ActiveWindow.ActivePane.View.Zoom.PageFit = wdPageFitBestFit Then
With ActiveWindow.ActivePane.View.Zoom
.PageColumns = 5
.PageRows = 2
End With
Else
With ActiveWindow.ActivePane.View.Zoom
.PageColumns = 1
.PageRows = 1
End With
ActiveWindow.ActivePane.View.Zoom.PageFit = wdPageFitBestFit
End If

End Sub

[Guessed]

Just to clean it up a little now you've solved it

Sub Toggle_View_Zoom()
  With ActiveWindow.ActivePane.View.Zoom
    If .PageFit = wdPageFitBestFit Then
      .PageColumns = 5
      .PageRows = 2
    Else
      .PageColumns = 1
      .PageRows = 1
      .PageFit = wdPageFitBestFit
    End If
  End With
End Sub

[eduzs]

Thanks! A lot cleaner.