Create bookmarks, links, or references throught doc

[jeffreybrown]

What is the best way to create bookmarks, links, or references throughout a doc?

I have some VBA to extract the references throughout the document that I would like to reference.

Sub FindInsideParanthesis()
    Dim StrOut As String
    With ActiveDocument
      With .Range
        With .Find
          .Text = "\(*\)"
          .MatchWildcards = True
          .Execute
        End With
        Do While .Find.Found = True
          StrOut = StrOut & vbCr & .Text
          .Collapse wdCollapseEnd
          .Find.Execute
        Loop
      End With
      .Range.InsertAfter StrOut
    End With
End Sub

This will place the references at the end of the document with the parenthesis attached, but I will remove the parenthesis first. I manual setup some examples in this document, but would like to automate this process.

[macropod]

You could, of course use an INDEX, in which case, you'd simply add XE fields at each of the found locations. For example:

Sub IndexParentheses()
Dim StrIdx As String
With ActiveDocument
  With .Range
    With .Find
      .Text = "\(*\)"
      .MatchWildcards = True
      .Execute
    End With
    Do While .Find.Found = True
      StrIdx = Replace(Replace(.Text, ")", Chr(34)), "(", Chr(34))
      .Collapse wdCollapseEnd
      .Fields.Add .Duplicate, wdFieldEmpty, "XE " & StrIdx, False
      .Find.Execute
    Loop
  End With
    .Indexes.Add Range:=.Range.Characters.Last, HeadingSeparator:=wdHeadingSeparatorNone, _
      Type:=wdIndexIndent, RightAlignPageNumbers:=True, NumberOfColumns:=1
End With
End Sub

No bookmarks or cross-references, per se, needed. The Index entries get sorted alphabetically and, if the same entry appears multiple times, grouped.

[jeffreybrown]

Thanks Paul. This will work well.