When check box is selected, need text to be written on bookmark

[Gogosaur]

I'm trying to create a form so that when users click a checkbox to request a certain document, a string of text will display in a bookmark on a word doc.



I have a checkbox named cbIEP that when checked, I want it to display "Request IEP" in the bookmark bmIEP.

Another checkbox named cbPsy that when checked, I want it to display "Request Psych Eval" in the bookmark bmPsy.

Thank you in advance

[Guessed]

Actually your checkboxes are named chckIEP and chckPsy

I would address this by adding the bookmark name and text values to the tag and ControlTipText properties on the relevant userform checkboxes. Then you implement the following code changes to the userform code - amend OK_Click and add the PopulateBM function.

Private Sub OK_Click()
  Application.ScreenUpdating = False
  With ActiveDocument
     .Bookmarks("bmDate").Range.Text = txtDate.Value
     .Bookmarks("bmName").Range.Text = txtName.Value
     .Bookmarks("bmUCI").Range.Text = txtUCI.Value
     .Bookmarks("bmDOB").Range.Text = txtDOB.Value
     .Bookmarks("bmSchool").Range.Text = txtSchool.Value
     .Bookmarks("bmIEPY").Range.Text = txtIEPY.Value
     .Bookmarks("bmPsyY").Range.Text = txtPsyY.Value
     .Bookmarks("bmSC").Range.Text = txtSC.Value
    PopulateBM Me.chckIEP
    PopulateBM Me.chckPsy
  End With
  Application.ScreenUpdating = True
  Unload Me
End Sub

Function PopulateBM(aCtl As Control)
  Dim sBkmk As String, sText As String
  sBkmk = aCtl.Tag
  sText = aCtl.ControlTipText
  With ActiveDocument
    If .Bookmarks.Exists(sBkmk) Then
      If aCtl Then
        .Bookmarks(sBkmk).Range.Text = sText
      Else
        .Bookmarks(sBkmk).Range.Text = ""
      End If
    End If
  End With
End Function

[gmayor]

Another way is to use the following macro to write your values to the bookmarks
You can then call it from your form e.g.

FillBM "bmDate", txtDate.Value
FillBM "bmName", txtName.Value

This ensures that the text is written IN the bookmark rather than AT it, thus enabling the values to be recalled to the userform should you wish to recall the userform to edit the document.
For optional insertions

If chckIEP.Value = True Then
    FillBM "bmIEP", "Request IEP"
Else
    FillBM "bmIEP", ""
End If

Public Sub FillBM(strbmName As String, strValue As String)
'Graham Mayor - http://www.gmayor.com
Dim orng As Range
    With ActiveDocument
        On Error GoTo lbl_Exit
        Set orng = .Bookmarks(strbmName).Range
        orng.Text = strValue
        orng.Bookmarks.Add strbmName
    End With
lbl_Exit:
    Set orng = Nothing
    Exit Sub
End Sub

[Guessed]

Graham is correct about the bookmark position not 'including' the text so you couldn't revisit the dialog multiple times. To resolve this on my previous code, the function should be amended to...

Function PopulateBM(aCtl As Control)
  Dim sBkmk As String, sText As String, aRng As Range
  sBkmk = aCtl.Tag
  sText = aCtl.ControlTipText
  With ActiveDocument
    If .Bookmarks.Exists(sBkmk) Then
      Set aRng = .Bookmarks(sBkmk).Range
      If aCtl Then
        aRng.Text = sText
      Else
        aRng.Text = ""
      End If
      aRng.Bookmarks.Add sBkmk
    End If
  End With
End Function

You could then query the values in those bookmarks to prefill the status of both settings as part of the UserForm_Initialize macro.

[gmayor]

While bookmarks are all very well and will certainly do the job, as both Andrew and I have indicated, I would suggest that you consider using content controls instead s they are more robust and harder for users to delete accidentally. I have modified some of your template to use controls. You can fill the rest yourself.

You don't need the date. Use a createdate field instead. Nor do you need the Clear button as this should be a template from which you create new documents.


As you have a combo box for the districts, make that a multiple column combo box and use the extra columns for the address parts.


It would be poissible to store the Districts and addresses in Excel and read them into the userform. You can find out how to do that from my web site.

[Gogosaur]

Thank you. I was able to manipulate the form with content control to do what I want but I'm still lost on how to get my original form to work.

I amended OK_Click, added the function and added my bookmark to the checkbox tag but I don't quite understand where I'm suppose to add the code to tell the form what I want it to say. Learning from scratch and it's bugging me not knowing where to go from there.

[gmayor]

See http://www.gmayor.com/Userform.htm