Drop down fields in Word - Change color of cell, then add text

[BernaDev202]

By reading previous threads on the subject, I've been able to create a color-coded drop down field in a Word table using the following:

Private Sub Document_ContentControlOnExit(ByVal ContentControl As ContentControl, Cancel As Boolean)
With ContentControl
  Select Case .Title
    Case "Relationship_Legal Team1"
      With .Range
        Select Case .Text
          Case "Advocate"
            .Cells(1).Shading.BackgroundPatternColorIndex = wdGreen
            .Font.ColorIndex = wdGreen
          Case "Endorser"
            .Cells(1).Shading.BackgroundPatternColorIndex = wdLightGreen
            .Font.ColorIndex = wdBrightGreen
          Case "Neutral"
            .Cells(1).Shading.BackgroundPatternColorIndex = wdDarkYellow
            .Font.ColorIndex = wdDarkYellow
          Case "Blocker"
            .Cells(1).Shading.BackgroundPatternColorIndex = wdRed
            .Font.ColorIndex = wdRed
          Case "None"
            .Cells(1).Shading.BackgroundPatternColorIndex = wdWhite
            .Font.ColorIndex = wdWhite
          Case Else
            .Cells(1).Shading.BackgroundPatternColorIndex = wdNoHighlight
            .Font.ColorIndex = wdAuto
        End Select
      End With
  End Select
End With

But is there a way for a user to also type text into the same field?

For instance, in the business development form I'm creating, the user selects a relationship type from the drop-down and the cell changes accordingly:



Relationship:
Advocate (Green)
Endorser (Bright Green)
Neutral (Dark Yellow)
Blocker (Red)
None (White)

Then, after the relationship type is selected and the cell changes color, I want the user to be able to add an initial (in white) to identify what type of power that relationship has:

D (Decision Maker)
A (Authority-wielder)
I (Influencer)
O (Observer)

It would ultimately look how it does in the attached image.

Any info would be much appreciated.

[macropod]

Perhaps:

Private Sub Document_ContentControlOnExit(ByVal CCtrl As ContentControl, Cancel As Boolean)
With CCtrl
  Select Case .Title
    Case "Relationship_Legal Team1"
      If .Type = wdContentControlDropdownList Then
        With .Range
          Select Case .Text
            Case "Advocate"
              .Cells(1).Shading.BackgroundPatternColorIndex = wdGreen
              .Font.ColorIndex = wdWhite
            Case "Endorser"
              .Cells(1).Shading.BackgroundPatternColorIndex = wdBrightGreen
              .Font.ColorIndex = wdWhite
            Case "Neutral"
              .Cells(1).Shading.BackgroundPatternColorIndex = wdDarkYellow
              .Font.ColorIndex = wdWhite
            Case "Blocker"
              .Cells(1).Shading.BackgroundPatternColorIndex = wdRed
              .Font.ColorIndex = wdWhite
            Case "None"
              .Cells(1).Shading.BackgroundPatternColorIndex = wdWhite
              .Font.ColorIndex = wdWhite
            Case Else
              .Cells(1).Shading.BackgroundPatternColorIndex = wdNoHighlight
              .Font.ColorIndex = wdAuto
            End Select
          End With
          If .ShowingPlaceholderText = False Then
            .Type = wdContentControlText
            .SetPlaceholderText , , "Input the Relationship Power"
            .Range.Text = ""
          End If
        Else
          .Range.Cells(1).Shading.BackgroundPatternColorIndex = wdNoHighlight
          .Range.Font.ColorIndex = wdAuto
          .Type = wdContentControlDropdownList
          .SetPlaceholderText , , "Choose a Relationship Type"
        End If
  End Select
End With
End Sub

PS: When posting code, please use the code tags, indicated by the # button on the posting menu. Without them, your code loses much of whatever structure it had.

[BernaDev202]

Thanks for the reply, but unfortunately it didn't work. When selecting from the drop down menu the cell color changed and an option did come up to input relationship power. However, the cell turned white again when text was entered.
Is there a code to change color of the next cell?

[macropod]

The only thing that changes colour when you enter the text is the actual text colour; the colour will, however, change to white again if you don't enter any text or if, having input something into the cell, you go back to change it. In the latter case, you'll have to reselect the Relationship from the dropdown.

As for changing the colour of the 'next' cell, that's quite easily done, though the code for that depends on whether that 'next' cell is on the same row.