VBA Find inexplicably aborts & goes to top

[mark99k]

What quirk in a document could cause this code to stop looking for more matches, (when there definitely are more):

Sub MarkParenthesizedItalicsNoProofing()
Selection.HomeKey wdStory
Selection.Find.ClearFormatting
With Selection.Find
    .Text = "\([A-Z][a-z.]@[!\)]@\)"
    .MatchWildcards = True
    .Wrap = False
    Do While .Execute
        Selection.MoveStart wdCharacter, 1
        Selection.MoveEnd wdCharacter, -1
        If Selection.Range.Italic = True Then
             Selection.Range.NoProofing = True
        End If
        Selection.Collapse wdCollapseEnd
    Loop
End With
End Sub

What happens: it stops looking, after finding several matches, sends the cursor to the top of the file, then flutters as if stuck in a loop, then hangs. No error message or other clues.

It only happens on certain files so I surmise it's something about those files and not the code, but for the life of me I can't figure out what's different about them. They vary widely but none are especially long or complex or old or mishandled. The point where the code stops looking varies, but if I copy & paste the first bunch of (successful) matches a dozen times, the macro will find *all* of those, then still freak out on one of the later ones. So the number of iterations seems to be irrelevant.



I've tried progressively more desperate simplifications, even not using Do While .Execute at all -- just a regular Find, then if .Found is True, collapse the selection and go to a label above the Find block. Even that variant crazily stops at a random point, goes to the top of the file and hangs.

I know this doesn't present well. I also know the Find feature can be quirky. Still, seems like this shouldn't happen. Any ideas? Using Word 2016, Windows 10 Pro.

Mark

[d4okeefe]

I would guess that some of your documents have text without a clear open/close parentheses. The wildcard search depends on that structure.

[mark99k]

Yeah that was my very first thought but it's not the case. In fact in the latest doc where it occurs, there are 3 properly closed pairs of parens on the same page, just south of where the macro surrenders & heads home.

(A separate routine runs on each file beforehand which, among other things, ensures all parens are paired.)

[d4okeefe]

Sorry that didn't work. I do think that you may be asking too much of the second half of the wildcard string. Maybe add ^13--and other special characters you see in your doc--to the square brackets, like so "\([A-Z][a-z.]@[!\)^13]@\)". This may prevent execute from crashing.

[mark99k]

No luck, same result. Why would adding ^13 help? I guess I should've explained, the purpose of this macro is to spot italicized botanical names in parens, for example (Coryphantha alversonii) and exclude them from the spell-checker. I can't think of a case where a paragraph mark would affect the search.

Thanks for your attention BTW.

[macropod]

The following should work.

Sub MarkParenthesizedItalicsNoProofing()
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Text = "\([A-Z][a-z.][!\(]@\)"
    .Replacement.Text = ""
    .Forward = True
    .Format = False
    .MatchWildcards = True
    .Wrap = wdFindStop
    .Execute
  End With
  Do While .Find.Found
    .Start = .Start + 1
    .End = .End - 1
    If .Font.Italic = True Then .NoProofing = True
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
End Sub

Note that there is a flaw in your own Find expression:
[!\)]
should be:
[!\(]
Otherwise it will fail if there are unmatched parentheses and the entire unmatched string is not italic.

[Guessed]

I'm not a fan of the selection object and I would think you need to be explicit in settintg the direction of the search. There also seems to be a flaw with the No Proofing not catching the first word if it is immediately preceded by a bracket. Try this variation

Sub MarkParenthesizedItalicsNoProofing()
  Dim aRng As Range, aSubRng As Range
  Set aRng = ActiveDocument.Range
  With aRng.Find
    .ClearFormatting
    .Text = "\([A-Z][a-z.]@[!\)]@\)"
    .MatchWildcards = True
    .Forward = True
    .Wrap = False
    Do While .Execute
      Set aSubRng = ActiveDocument.Range(aRng.Start + 1, aRng.End - 1)
      aRng.NoProofing = aSubRng.Italic = True
      aRng.Collapse wdCollapseEnd
    Loop
  End With
End Sub

[mark99k]

Thanks to macropod/Paul and Guessed/Andrew. I'm also not a Selection junkie at heart, but my many prior attempts using ranges fell flat, and debugging felt marginally simpler with the text visible. HOWEVER, both of your replies indirectly pointed me to the actual root of the issue, which is:

This document -- and apparently all of the others in which my original code routinely failed -- contains fields whose results contain parens, and those fields confound the adjustments needed to check for italic font within the parens. (Sure enough, the Execute loop went south right when it got to the first such field. Agh.

I haven't fixed it yet but it should be straightfoward now. Thanks so much to both of you.

[macropod]

Trying to update field results via a Find/Replace is fairly pointless, since anything that causes Word to refresh the field display will wipe out your edits. And, as I said, your Find expression was itself flawed.

[mark99k]

Yes I know, and I appreciate the fix to the expression. None of the fields in these docs ever contained, or ever will contain, the botanical names being targeted, so I'll just write around them. The fields are the reason the selection (or range) suddenly died when the macro tried to exclude its parens to check the font (since a field actually counts as just one character).

[macropod]

Perhaps you could attach a document to a post with some representative data (delete anything sensitive) demonstrating the problem you're having with fields? You can do this via the paperclip symbol on the 'Go Advanced' tab at the bottom of this screen.

[mark99k]

Sure, if you're interested, but again, there's no urgency now; I can code around it. Short excerpt is attached. It's from an unreleased government document but I've greeked most of the text.

In the sample, the callout for Table 4.4-1 (incl its title) is a REF field, and you can see italic scientific names above & below it. Your code runs fine if I take out that field, but hangs if it's left in.

[macropod]

It don't know why you'd have an opening parenthesis within a field code but the closing one outside it. That said, you might try:

Sub MarkParenthesizedItalicsNoProofing()
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Text = "\([A-Z][a-z.][!\(]@\)"
    .Replacement.Text = ""
    .Forward = True
    .Format = False
    .MatchWildcards = True
    .Wrap = wdFindStop
    .Execute
  End With
  Do While .Find.Found
    .Start = .Start + 1
    .End = .End - 1
    If Len(.Text) = 0 Then
      .End = .End + 1
    Else
      If .Font.Italic = True Then .NoProofing = True
    End If
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
End Sub

[mark99k]

Thanks Paul, this is beautiful. I did stumble over one quirk: at unpredictable times the first word in parens (when there's more than one, which is common) won't escape the spell-checker unless I also include the opening paren in the range to be set to NoProofing, so that part is now:

If .Font.Italic = True Then
    .Start = .Start -1
    .NoProofing = True
End If

And yes, the field-straddling parentheses are truly bizarre but they aren't mine and we're forbidden to touch them.

Thanks again.