Word macro to change ALL CAPS to UPPERCASE

[dita]

Hello guys,

Is there any way to create a macro to change all instances of ALL CAPS to uppercase?

I tried to create it by using wildcards but there is no way to replace all instances to uppercase (not available in the wildcard menu).

Thank you in advance!

[eduzs]

Try this:

Backup the original file and code before doing any modification, test before use, use at your own.

Sub Macro3()
With ActiveDocument.Range
With .Find
.Text = "*"
.Font.AllCaps = True
.Replacement.Font.AllCaps = False
.Replacement.Text = "^&"
.Forward = True
.Wrap = wdFindStop
.MatchWildcards = True
.Format = True
.Execute
End With
Do While .Find.Found
.Case = wdUpperCase
.Collapse wdCollapseEnd
.Find.Execute
Loop
End With
End Sub

[dita]

It works!

I will try to tweak your code to make another find/replace.

Thanks so much!

[macropod]

Why do you need a macro at all to "change all instances of ALL CAPS to uppercase"? All you need do is choose 'UPPERCASE' from the 'Change Case' dropdown...

[dita]

Originally Posted by macropod

Why do you need a macro at all to "change all instances of ALL CAPS to uppercase"? All you need do is choose 'UPPERCASE' from the 'Change Case' dropdown...

As far as I know there is no way to select the option UPPERCASE in the wildcards. Otherwise, we should change all instances one by one.

[macropod]

Originally Posted by dita

As far as I know there is no way to select the option UPPERCASE in the wildcards. Otherwise, we should change all instances one by one.

You're missing the point - you don't need a macro at all (just select the whole document and use the 'Change Case' dropdown's 'UPPERCASE' option) or, if you're wedded to using a macro, anything to do with Find/Replace, hence:

Sub Demo(): ActiveDocument.Range.Case = wdUpperCase: End Sub

There it is, all in one line and way faster than eduzs' code.

[eduzs]

Hi Macropod,

In the code above ".Collapse wdCollapseEnd" is really necessary? What it does?

Thanks

[Guessed]

The Collapse end is there to ensure that the previously found item is not re-found.

Instead, it moves to the end of the previously found range to continue searching forward from that point.

[eduzs]

Superb! Thank you! I was planning to remove this line, not anymore!

[eduzs]

So I understand it might have parts of the text the is is lowercase (must be in lowercase), so can't set all uppercase at once.

[macropod]

Well, if the document contains mixed cases and you only want to change those ranges, you could use a Find/Replace macro, but such a macro could be simpler and faster than yours:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Text = ""
    .Font.AllCaps = True
    .Forward = True
    .MatchWildcards = False
    .Wrap = wdFindStop
    .Execute
  End With
  Do While .Find.Found = True
    .Case = wdUpperCase
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
End Sub

[dita]

Hi guys,

I posted a question similar to this in another thread but would need to go further on this function.

I have a document which have certain parts of text in ALL CAPS and some others in SMALL CAPS.

So I am looking for a macro that changes such instances of text in "ALL CAPS" to uppercase. And any piece of text in "SMALL CAPS" to lowercase.

Can this be done with a macro in one go?

Many thanks!

[eduzs]

You asked something like this in my post above that you can use as a response with only minor adaptations.

[dita]

That´s correct. However, I tried to tweak the code provided in the other post but did not work when I added the case change SMALL CAPS to lowercase:

With ActiveDocument.Range
With .Find
.Text = "*"
.Font.ALLCAPS = True
.Replacement.Font.ALLCAPS = False
.Replacement.Text = "^&"
.Forward = True
.Wrap = wdFindStop
.MatchWildcards = True
.Format = True
.Execute
End With
Do While .Find.Found
.Case = wdUpperCase
.Collapse wdCollapseEnd
.Find.Execute
Loop
End With
With ActiveDocument.Range
With .Find
.Text = "*"
.Font.SmallCaps = True
.Replacement.Font.SmallCaps = False
.Replacement.Text = "^&"
.Forward = True
.Wrap = wdFindStop
.MatchWildcards = True
.Format = True
.Execute
End With
Do While .Find.Found
.Case = wdLowerCase
.Collapse wdCollapseEnd
.Find.Execute
Loop
End With
End Sub

[macropod]

Try:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Forward = True
    .MatchWildcards = False
    .Text = ""
    .Font.SmallCaps = True
    .Replacement.Font.SmallCaps = False
    .Wrap = wdFindContinue
    .Execute Replace:=wdReplaceAll
    .Font.AllCaps = True
    .Wrap = wdFindStop
    .Execute
  End With
  Do While .Find.Found = True
    .Case = wdUpperCase
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
End Sub

PS: When posting code, please use the code tags, indicated by the # button on the posting menu. Without them, your code loses much of whatever structure it had.

PPS: When posting about related topics, please keep the posts in the same thread. Threads merged.