Word macro to change ALL CAPS to UPPERCASE

dita · #1 04-29-2018, 03:21 AM

Hello guys,

Is there any way to create a macro to change all instances of ALL CAPS to uppercase?

I tried to create it by using wildcards but there is no way to replace all instances to uppercase (not available in the wildcard menu).

Thank you in advance!

eduzs · #2 04-29-2018, 07:25 AM

Try this:

Backup the original file and code before doing any modification, test before use, use at your own.

Quote:

Sub Macro3()
With ActiveDocument.Range
With .Find
.Text = "*"
.Font.AllCaps = True
.Replacement.Font.AllCaps = False
.Replacement.Text = "^&"
.Forward = True
.Wrap = wdFindStop
.MatchWildcards = True
.Format = True
.Execute
End With
Do While .Find.Found
.Case = wdUpperCase
.Collapse wdCollapseEnd
.Find.Execute
Loop
End With
End Sub

dita · #3 04-29-2018, 09:25 AM

It works!

I will try to tweak your code to make another find/replace.

Thanks so much!

macropod · #4 04-29-2018, 09:18 PM

Why do you need a macro at all to "change all instances of ALL CAPS to uppercase"? All you need do is choose 'UPPERCASE' from the 'Change Case' dropdown...

eduzs · #5 04-30-2018, 02:44 AM

Hi Macropod,

In the code above ".Collapse wdCollapseEnd" is really necessary? What it does?

Thanks

Guessed · #6 04-30-2018, 04:34 AM

The Collapse end is there to ensure that the previously found item is not re-found.

Instead, it moves to the end of the previously found range to continue searching forward from that point.

eduzs · #7 04-30-2018, 04:35 AM

Superb! Thank you! I was planning to remove this line, not anymore!

dita · #8 04-30-2018, 06:12 AM

Quote:

Originally Posted by macropod

Why do you need a macro at all to "change all instances of ALL CAPS to uppercase"? All you need do is choose 'UPPERCASE' from the 'Change Case' dropdown...

As far as I know there is no way to select the option UPPERCASE in the wildcards. Otherwise, we should change all instances one by one.

macropod · #9 04-30-2018, 02:34 PM

Quote:

Originally Posted by dita

As far as I know there is no way to select the option UPPERCASE in the wildcards. Otherwise, we should change all instances one by one.

You're missing the point - you don't need a macro at all (just select the whole document and use the 'Change Case' dropdown's 'UPPERCASE' option) or, if you're wedded to using a macro, anything to do with Find/Replace, hence:

Code:

Sub Demo(): ActiveDocument.Range.Case = wdUpperCase: End Sub

There it is, all in one line and way faster than eduzs' code.

eduzs · #10 04-30-2018, 04:13 PM

So I understand it might have parts of the text the is is lowercase (must be in lowercase), so can't set all uppercase at once.

macropod · #11 04-30-2018, 05:24 PM

Well, if the document contains mixed cases and you only want to change those ranges, you could use a Find/Replace macro, but such a macro could be simpler and faster than yours:

Code:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Text = ""
    .Font.AllCaps = True
    .Forward = True
    .MatchWildcards = False
    .Wrap = wdFindStop
    .Execute
  End With
  Do While .Find.Found = True
    .Case = wdUpperCase
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
End Sub

dita · #12 05-20-2018, 01:02 AM

Hi guys,

I posted a question similar to this in another thread but would need to go further on this function.

I have a document which have certain parts of text in ALL CAPS and some others in SMALL CAPS.

So I am looking for a macro that changes such instances of text in "ALL CAPS" to uppercase. And any piece of text in "SMALL CAPS" to lowercase.

Can this be done with a macro in one go?

Many thanks!

eduzs · #13 05-20-2018, 04:00 AM

You asked something like this in my post above that you can use as a response with only minor adaptations.

dita · #14 05-20-2018, 10:55 AM

That´s correct. However, I tried to tweak the code provided in the other post but did not work when I added the case change SMALL CAPS to lowercase:

With ActiveDocument.Range
With .Find
.Text = "*"
.Font.ALLCAPS = True
.Replacement.Font.ALLCAPS = False
.Replacement.Text = "^&"
.Forward = True
.Wrap = wdFindStop
.MatchWildcards = True
.Format = True
.Execute
End With
Do While .Find.Found
.Case = wdUpperCase
.Collapse wdCollapseEnd
.Find.Execute
Loop
End With
With ActiveDocument.Range
With .Find
.Text = "*"
.Font.SmallCaps = True
.Replacement.Font.SmallCaps = False
.Replacement.Text = "^&"
.Forward = True
.Wrap = wdFindStop
.MatchWildcards = True
.Format = True
.Execute
End With
Do While .Find.Found
.Case = wdLowerCase
.Collapse wdCollapseEnd
.Find.Execute
Loop
End With
End Sub

macropod · #15 05-20-2018, 10:56 PM

Try:

Code:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Forward = True
    .MatchWildcards = False
    .Text = ""
    .Font.SmallCaps = True
    .Replacement.Font.SmallCaps = False
    .Wrap = wdFindContinue
    .Execute Replace:=wdReplaceAll
    .Font.AllCaps = True
    .Wrap = wdFindStop
    .Execute
  End With
  Do While .Find.Found = True
    .Case = wdUpperCase
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
End Sub

PS: When posting code, please use the code tags, indicated by the # button on the posting menu. Without them, your code loses much of whatever structure it had.

PPS: When posting about related topics, please keep the posts in the same thread. Threads merged.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Need a Macro to Change Every Instance of Small Caps to All Caps and Reduce the Font by 2 Points	CrossReach	Word VBA	2	11-13-2017 09:21 AM
How to find CAPITALIZED names and change them into small caps	dylan.ve	Word VBA	5	02-25-2016 03:15 PM
Change lower case to caps whole document	lmb100	Word	4	08-07-2015 06:57 AM
Using conditional formatining to change to all caps	Shades	Excel	3	05-05-2014 06:05 AM
find&replace word in uppercase with word in lowercase	andrei	Word	3	10-03-2011 05:11 AM