how to add building blocks in Word by VBA also in footer

[avogt]

Hello,

I want to add building blocks in my Word Document by VBA.
How can I place them correctly?

How can I place them in the footer?

ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageFooter
        ActiveDocument.Range(ActiveDocument.Bookmarks("start").Range.Start + 1, ActiveDocument.Bookmarks("ende").Range.Start).Select
        Set objTemplate = Templates(1)
        Set objBB = objTemplate.BuildingBlockEntries.Item("Fusszeile_geschäftlich_DE")
        objBB.Insert Selection.Range
ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument

does not work.. :-(

Thanks,


Andreas

[gmayor]

The following function will insert a building block from a named template at a bookmarked location. That bookmark can be in a footer. See also thew example at https://www.gmayor.com/word_vba_examples_3.htm

Sub AutoTextToBM(strbmName As String, oTemplate As Template, strAutotext As String)
'strBMName is the name of the bookmark to fill
'oTemplate is the template with the autotext - probably ActiveDocument.AttachedTemplate
'strAutotext is the name of the autotext entry
Dim oRng As Range
    On Error GoTo lbl_Exit
    With ActiveDocument
        Set oRng = .Bookmarks(strbmName).Range
        Set oRng = oTemplate.AutoTextEntries(strAutotext).Insert _
                   (Where:=oRng, RichText:=True)
        .Bookmarks.Add Name:=strbmName, Range:=oRng
    End With
lbl_Exit:
    Exit Sub
End Sub

[avogt]

Hi,
is there an other possibility to add the building block instead of a bookmarkt?

If not, the only way would be to delete all bookmarks after the macro has run..?

I am using the VBA to create templates depending on a menue, where the user chooses the template and some parameters.. (language, invoice/offer/.., and date..).

So I have a blank dotm and the VBA inserts all blocks, which will be needed..

is there a function to add an building block "after" something? e.g. after I inserted blockA, I will get a vbcrlf and then add blockB..

thanks,
Andreas

[gmayor]

Frankly you can insert building blocks anywhere practical. If you want to insert a sequernce of building blocks at a range then try the following function

Sub AutoTextToRange(oRng As Range, oTemplate As Template, strAutotext As String)
'oRng is the name of the range to Place
'oTemplate is the template with the autotext - probably ActiveDocument.AttachedTemplate
'strAutotext is the name of the autotext entry
    Set oRng = oTemplate.AutoTextEntries(strAutotext).Insert _
               (Where:=oRng, RichText:=True)
    oRng.Collapse 0
    oRng.Select
lbl_Exit:
    Exit Sub
End Sub

You can call that as many times as you have building blocks to insert. Each time it puts the selection at the end of the building block. The following puts two building blocks consecutively at the cursor.

You could instead insert the first one at a range and the rest will follow.

AutoTextToRange Selection.Range, ActiveDocument.AttachedTemplate, "BBName1"
AutoTextToRange Selection.Range, ActiveDocument.AttachedTemplate, "BBName2"